mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-29 22:07:26 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
63 lines
1.7 KiB
Bash
63 lines
1.7 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python2_7 ) # still only supports py2
|
|
|
|
inherit distutils-r1 versionator
|
|
|
|
MY_PV="$(replace_all_version_separators '_' )"
|
|
DESCRIPTION="Python bindings for Network Security Services (NSS)"
|
|
HOMEPAGE="http://www.mozilla.org/projects/security/pki/python-nss/"
|
|
SRC_URI="ftp://ftp.mozilla.org/pub/mozilla.org/security/${PN}/releases/PYNSS_RELEASE_${MY_PV}/src/${P}.tar.bz2"
|
|
|
|
LICENSE="|| ( MPL-1.1 GPL-2 LGPL-2 )"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="doc examples"
|
|
|
|
DEPEND="dev-libs/nss
|
|
dev-libs/nspr
|
|
doc? ( dev-python/docutils[${PYTHON_USEDEP}]
|
|
dev-python/epydoc[${PYTHON_USEDEP}] )"
|
|
RDEPEND="${DEPEND}"
|
|
|
|
CFLAGS="${CFLAGS} -fno-strict-aliasing"
|
|
DOCS="README doc/ChangeLog"
|
|
|
|
python_prepare_all() {
|
|
# Remove test file using a dep, called nss-tools, unavailable in portage
|
|
rm -f test/test_pkcs12.py || die
|
|
sed -e '/import test_pkcs12/d' \
|
|
-e '/suite.addTests(loader.loadTestsFromModule(test_pkcs12))/d' \
|
|
-i test/run_tests || die
|
|
|
|
# exclude tests due to absent shared lib file, libnssckbi.so
|
|
sed -e 's:test_ocsp_default_responder:_&:' \
|
|
-i test/test_ocsp.py || die
|
|
sed -e 's:test_ssl:_&:' \
|
|
-i test/test_client_server.py || die
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
if use doc; then
|
|
einfo "Generating API documentation..."
|
|
mkdir doc/html
|
|
epydoc --html --docformat restructuredtext -o doc/html \
|
|
"${BUILD_DIR}"/lib/nss
|
|
fi
|
|
}
|
|
|
|
python_test() {
|
|
"${PYTHON}" test/run_tests || die
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( doc/html/. )
|
|
use examples && local EXAMPLES=( doc/examples/. )
|
|
|
|
distutils-r1_python_install_all
|
|
}
|