mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-30 04:47:28 -07:00
4e20076487
Also avoid compressing examples, fix manpage installation. Package-Manager: Portage-2.3.71, Repoman-2.3.16 Signed-off-by: Louis Sautier <sbraz@gentoo.org>
53 lines
1.2 KiB
Bash
53 lines
1.2 KiB
Bash
# Copyright 1999-2019 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
|
|
|
|
inherit distutils-r1
|
|
|
|
if [[ ${PV} == 9999 ]]; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://github.com/tqdm/tqdm"
|
|
else
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
KEYWORDS="~amd64 ~x86"
|
|
fi
|
|
|
|
DESCRIPTION="Add a progress meter to your loops in a second"
|
|
HOMEPAGE="https://github.com/tqdm/tqdm"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
IUSE="examples test"
|
|
|
|
# Uses pkg_resources
|
|
RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
|
|
BDEPEND="
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
test? ( dev-python/nose[${PYTHON_USEDEP}] )
|
|
"
|
|
|
|
python_test() {
|
|
# tests_main.py requires the package to be installed
|
|
distutils_install_for_testing
|
|
# Skip unpredictable performance tests
|
|
nosetests tqdm -v -I 'tests_perf.py' \
|
|
|| die "tests failed with ${EPYTHON}"
|
|
}
|
|
|
|
python_install() {
|
|
doman "${BUILD_DIR}"/lib/tqdm/tqdm.1
|
|
rm "${BUILD_DIR}"/lib/tqdm/tqdm.1 || die
|
|
distutils-r1_python_install --skip-build
|
|
}
|
|
|
|
python_install_all() {
|
|
if use examples; then
|
|
dodoc -r examples
|
|
docompress -x /usr/share/doc/${PF}/examples
|
|
fi
|
|
distutils-r1_python_install_all
|
|
}
|