mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-03-03 08:47:28 -08:00
f74fabfe65
Thanks-to: Juergen Rose <rose@rz.uni-potsdam.de> Closes: https://bugs.gentoo.org/685780 Package-Manager: Portage-2.3.69, Repoman-2.3.16 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
52 lines
1.1 KiB
Bash
52 lines
1.1 KiB
Bash
# Copyright 1999-2019 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Message Passing Interface for Python"
|
|
HOMEPAGE="https://bitbucket.org/mpi4py/ https://pypi.org/project/mpi4py/"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
|
|
IUSE="doc examples test"
|
|
|
|
RDEPEND="virtual/mpi"
|
|
DEPEND="${RDEPEND}
|
|
test? (
|
|
dev-python/nose[${PYTHON_USEDEP}]
|
|
virtual/mpi[romio]
|
|
)
|
|
"
|
|
|
|
DISTUTILS_IN_SOURCE_BUILD=1
|
|
|
|
python_prepare_all() {
|
|
# not needed on install
|
|
rm -vr docs/source || die
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
src_compile() {
|
|
export FAKEROOTKEY=1
|
|
distutils-r1_src_compile
|
|
}
|
|
|
|
python_test() {
|
|
echo "Beginning test phase"
|
|
pushd "${BUILD_DIR}"/../ &> /dev/null || die
|
|
mpiexec -n 2 "${PYTHON}" ./test/runtests.py -v || die "Testsuite failed under ${EPYTHON}"
|
|
popd &> /dev/null || die
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( docs/. )
|
|
use examples && local DOCS=( demo )
|
|
distutils-r1_python_install_all
|
|
}
|