mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-29 04:27:34 -07:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
72 lines
1.6 KiB
Bash
72 lines
1.6 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python{2_7,3_3} pypy )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_PN="redis"
|
|
MY_P="${MY_PN}-${PV}"
|
|
|
|
DESCRIPTION="Python client for Redis key-value store"
|
|
HOMEPAGE="http://github.com/andymccurdy/redis-py http://pypi.python.org/pypi/redis"
|
|
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 x86"
|
|
IUSE="test"
|
|
|
|
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
|
|
test? ( dev-db/redis )"
|
|
RDEPEND=""
|
|
|
|
S="${WORKDIR}/${MY_P}"
|
|
|
|
python_prepare_all() {
|
|
# Disable pubsub and encoding tests, they do not seem to support
|
|
# UNIX socket connectivity.
|
|
sed -i -e '/PubSub/d' -e '/Encoding/d' \
|
|
-e '/use_hiredis:/d' tests/__init__.py || die
|
|
|
|
# Make sure that tests will be used from BUILD_DIR rather than cwd.
|
|
mv tests tests-hidden || die
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile() {
|
|
distutils-r1_python_compile
|
|
|
|
if use test; then
|
|
cp -r tests-hidden "${BUILD_DIR}"/tests || die
|
|
fi
|
|
}
|
|
|
|
src_test() {
|
|
# local DISTUTILS_NO_PARALLEL_BUILD=1
|
|
|
|
distutils-r1_src_test
|
|
}
|
|
|
|
python_test() {
|
|
local pidfile=${T}/redis-${EPYTHON}.pid
|
|
local sock=${T}/redis-${EPYTHON}.sock
|
|
|
|
sed -i -e "s:port=6379:unix_socket_path=\"${sock}\":" \
|
|
"${BUILD_DIR}"/tests/*.py || die
|
|
|
|
# XXX: find a way to make sure it is killed
|
|
|
|
"${EPREFIX}"/usr/sbin/redis-server \
|
|
--pidfile "${pidfile}" \
|
|
--port 0 \
|
|
--unixsocket "${sock}" \
|
|
--daemonize yes || die
|
|
PYTHONPATH="${PYTHONPATH}:${BUILD_DIR}" \
|
|
esetup.py test
|
|
kill "$(<"${pidfile}")"
|
|
}
|