mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-08 01:07:30 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
62 lines
1.9 KiB
Bash
62 lines
1.9 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI="5"
|
|
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy3 )
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="py.test: simple powerful testing with Python"
|
|
HOMEPAGE="http://pytest.org/ http://pypi.python.org/pypi/pytest"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
|
|
IUSE="doc test"
|
|
|
|
# When bumping, please check setup.py for the proper py version
|
|
PY_VER="1.4.29"
|
|
RDEPEND=">=dev-python/py-${PY_VER}[${PYTHON_USEDEP}]"
|
|
|
|
#pexpect dep based on https://bitbucket.org/hpk42/pytest/issue/386/tests-fail-with-pexpect-30
|
|
DEPEND="${RDEPEND}
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
test? ( dev-python/pexpect[${PYTHON_USEDEP}] )
|
|
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
|
|
|
|
python_prepare_all() {
|
|
# Disable versioning of py.test script to avoid collision with
|
|
# versioning performed by the eclass.
|
|
sed -e "s/return points/return {'py.test': target}/" -i setup.py || die "sed failed"
|
|
grep -qF "py>=${PY_VER}" setup.py || die "Incorrect dev-python/py dependency"
|
|
|
|
# Prevent un-needed d'loading
|
|
sed -e "s/'sphinx.ext.intersphinx', //" -i doc/en/conf.py || die
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
if use doc; then
|
|
mkdir doc/en/.build || die
|
|
emake -C doc/en html
|
|
fi
|
|
}
|
|
|
|
python_test() {
|
|
# test_nose.py not written to suit py3.2 in pypy3
|
|
if [[ "${EPYTHON}" == pypy3 ]]; then
|
|
"${PYTHON}" "${BUILD_DIR}"/lib/pytest.py \
|
|
--ignore=testing/test_nose.py \
|
|
|| die "tests failed with ${EPYTHON}"
|
|
else
|
|
"${PYTHON}" "${BUILD_DIR}"/lib/pytest.py \
|
|
|| die "tests failed with ${EPYTHON}"
|
|
fi
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && dohtml -r doc/en/_build/html/
|
|
distutils-r1_python_install_all
|
|
}
|