mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-08 01:07:30 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
45 lines
1.2 KiB
Bash
45 lines
1.2 KiB
Bash
# Copyright 1999-2014 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
PYTHON_COMPAT=( python{2_7,3_3} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="A jQuery-like library for python"
|
|
HOMEPAGE="http://pypi.python.org/pypi/pyquery"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="alpha amd64 arm ~hppa ia64 ppc ~ppc64 s390 sh sparc x86 ~x86-fbsd"
|
|
IUSE="beautifulsoup3 test"
|
|
|
|
RDEPEND=">=dev-python/lxml-2.1[beautifulsoup3?,${PYTHON_USEDEP}]
|
|
dev-python/cssselect[${PYTHON_USEDEP}]
|
|
>=dev-python/webob-1.2_rc1[${PYTHON_USEDEP}]"
|
|
DEPEND="${RDEPEND}
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
test? ( dev-python/nose[${PYTHON_USEDEP}] )"
|
|
REQUIRED_USE="test? ( beautifulsoup3 )"
|
|
|
|
DOCS=( CHANGES.rst README.rst )
|
|
|
|
python_prepare_all() {
|
|
# Disable tests that access the net
|
|
for file in docs/{ajax.txt,manipulating.txt,scrap.txt,tips.txt}
|
|
do
|
|
mv ${file} ${file/.txt/} || die
|
|
done
|
|
sed -e 's:>>> d = pq(url:>>> # d = pq(url:' -i README.rst || die
|
|
sed -e 's:class TestWebScrapping:class _TestWebScrapping:' -i ${PN}/test.py || die
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_test() {
|
|
nosetests || die "Tests fail with ${EPYTHON}"
|
|
}
|