mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-09 01:27:34 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
50 lines
1.3 KiB
Bash
50 lines
1.3 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python{2_7,3_3} pypy )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_PN="Pygments"
|
|
MY_P="${MY_PN}-${PV}"
|
|
|
|
DESCRIPTION="Pygments is a syntax highlighting package written in Python"
|
|
HOMEPAGE="http://pygments.org/ http://pypi.python.org/pypi/Pygments"
|
|
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
|
|
IUSE="doc test"
|
|
|
|
RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
|
|
DEPEND="${RDEPEND}
|
|
test? (
|
|
dev-python/nose[${PYTHON_USEDEP}]
|
|
virtual/ttf-fonts
|
|
dev-texlive/texlive-latexrecommended
|
|
)"
|
|
|
|
S="${WORKDIR}/${MY_P}"
|
|
|
|
python_test() {
|
|
cp -r -l tests "${BUILD_DIR}"/ || die
|
|
|
|
if [[ ${EPYTHON} == python3.* ]]; then
|
|
# Notes:
|
|
# -W is not supported by python3.1
|
|
# -n causes Python to write into hardlinked files
|
|
2to3 --no-diffs -w "${BUILD_DIR}"/tests/*.py || die
|
|
fi
|
|
|
|
nosetests -w "${BUILD_DIR}"/tests || die "Tests fail with ${EPYTHON}"
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( docs/build/. )
|
|
|
|
distutils-r1_python_install_all
|
|
}
|