mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-08 13:17:38 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
74 lines
1.8 KiB
Bash
74 lines
1.8 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
PYTHON_COMPAT=( python2_7 python3_{3,4} )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_PN="Paste"
|
|
MY_P="${MY_PN}-${PV}"
|
|
|
|
DESCRIPTION="Tools for using a Web Server Gateway Interface stack"
|
|
HOMEPAGE="http://pythonpaste.org http://pypi.python.org/pypi/Paste"
|
|
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 ~ppc ~ppc64 x86 ~x86-interix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris"
|
|
IUSE="doc flup openid"
|
|
|
|
RDEPEND="
|
|
dev-python/six[${PYTHON_USEDEP}]
|
|
>=dev-python/tempita-0.5.2_pre20130828[${PYTHON_USEDEP}]
|
|
flup? ( dev-python/flup[$(python_gen_usedep 'python2*')] )
|
|
openid? ( dev-python/python-openid[$(python_gen_usedep 'python2*')] )"
|
|
DEPEND="${RDEPEND}
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
|
|
|
|
S="${WORKDIR}/${MY_P}"
|
|
|
|
python_prepare_all() {
|
|
# Disable failing tests.
|
|
rm -f tests/test_cgiapp.py || die
|
|
sed \
|
|
-e "s/test_find_file/_&/" \
|
|
-e "s/test_deep/_&/" \
|
|
-e "s/test_static_parser/_&/" \
|
|
-i tests/test_urlparser.py || die "sed failed"
|
|
|
|
# Remove a test that runs against the paste website.
|
|
rm -f tests/test_proxy.py || die
|
|
|
|
local PATCHES=(
|
|
"${FILESDIR}"/${PN}-1.7.5.1-fix-tests-for-pypy.patch
|
|
"${FILESDIR}"/${P}-unbundle-tempita.patch
|
|
)
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile() {
|
|
distutils-r1_python_compile egg_info --egg-base "${BUILD_DIR}/lib"
|
|
}
|
|
|
|
python_compile_all() {
|
|
use doc && esetup.py build_sphinx
|
|
}
|
|
|
|
python_test() {
|
|
nosetests -P -v || die "Tests fail with ${EPYTHON}"
|
|
}
|
|
|
|
python_install() {
|
|
distutils-r1_python_install egg_info --egg-base "${BUILD_DIR}/lib"
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
|
|
distutils-r1_python_install_all
|
|
}
|