mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-08 13:17:38 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
75 lines
2.1 KiB
Bash
75 lines
2.1 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
PYTHON_COMPAT=( python2_7 python3_{3,4} )
|
|
|
|
inherit distutils-r1 flag-o-matic
|
|
|
|
DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
|
|
HOMEPAGE="http://lxml.de/ http://pypi.python.org/pypi/lxml/"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="BSD ElementTree GPL-2 PSF-2"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris ~arm64"
|
|
IUSE="beautifulsoup3 doc examples +threads test"
|
|
|
|
# Note: lib{xml2,xslt} are used as C libraries, not Python modules.
|
|
RDEPEND="
|
|
>=dev-libs/libxml2-2.7.2
|
|
>=dev-libs/libxslt-1.1.23
|
|
beautifulsoup3? (
|
|
$(python_gen_cond_dep 'dev-python/beautifulsoup:python-2[${PYTHON_USEDEP}]' 'python2*')
|
|
$(python_gen_cond_dep 'dev-python/beautifulsoup:python-3[${PYTHON_USEDEP}]' 'python3*')
|
|
)"
|
|
DEPEND="${RDEPEND}
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
test? ( dev-python/cssselect[${PYTHON_USEDEP}] )
|
|
"
|
|
# lxml tarball contains files pregenerated by Cython.
|
|
|
|
DISTUTILS_IN_SOURCE_BUILD=1
|
|
|
|
python_prepare_all() {
|
|
# avoid replacing PYTHONPATH in tests.
|
|
sed -i '/sys\.path/d' test.py || die
|
|
|
|
# seems to be broken
|
|
rm src/lxml/tests/test_elementpath.py || die
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile() {
|
|
if [[ ${EPYTHON} != python3* ]]; then
|
|
local CFLAGS=${CFLAGS}
|
|
append-cflags -fno-strict-aliasing
|
|
fi
|
|
distutils-r1_python_compile
|
|
}
|
|
|
|
python_test() {
|
|
cp -r -l src/lxml/tests "${BUILD_DIR}"/lib/lxml/ || die
|
|
cp -r -l src/lxml/html/tests "${BUILD_DIR}"/lib/lxml/html/ || die
|
|
ln -s "${S}"/doc "${BUILD_DIR}"/ || die
|
|
|
|
local test
|
|
for test in test.py selftest.py selftest2.py; do
|
|
einfo "Running ${test}"
|
|
"${PYTHON}" ${test} -vv -p || die "Test ${test} fails with ${EPYTHON}"
|
|
done
|
|
}
|
|
|
|
python_install_all() {
|
|
if use doc; then
|
|
local DOCS=( *.txt doc/*.txt )
|
|
local HTML_DOCS=( doc/html/. )
|
|
fi
|
|
use examples && local EXAMPLES=( samples/. )
|
|
|
|
distutils-r1_python_install_all
|
|
}
|