mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-30 16:57:29 -07:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
68 lines
1.8 KiB
Bash
68 lines
1.8 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python2_7 )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_PN="Fabric"
|
|
MY_P="${MY_PN}-${PV}"
|
|
|
|
DESCRIPTION="A simple pythonic tool for remote execution and deployment"
|
|
HOMEPAGE="http://fabfile.org http://pypi.python.org/pypi/Fabric"
|
|
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
|
|
|
|
LICENSE="GPL-2"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 x86"
|
|
IUSE="doc test"
|
|
|
|
RDEPEND="
|
|
>=dev-python/paramiko-1.10[${PYTHON_USEDEP}]"
|
|
DEPEND="${RDEPEND}
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
|
|
>=dev-python/python-docs-2.7.6-r1:2.7
|
|
dev-python/alabaster[${PYTHON_USEDEP}] )
|
|
test? ( dev-python/nose[${PYTHON_USEDEP}]
|
|
<dev-python/fudge-1.0[${PYTHON_USEDEP}]
|
|
dev-python/jinja[${PYTHON_USEDEP}] )"
|
|
|
|
S="${WORKDIR}/${MY_P}"
|
|
|
|
python_prepare_all() {
|
|
# Re-set intersphinx_mapping for doc build
|
|
if use doc; then
|
|
local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
|
|
local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
|
|
local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
|
|
local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
|
|
sed -e "s|'http://docs.python.org/2.6', None|'${PYTHON_DOC}', '${PYTHON_DOC_INVENTORY}'|" \
|
|
-e "s| 'www'| #'www'|" \
|
|
-i sites/docs/conf.py || die
|
|
fi
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
if use doc; then
|
|
sphinx-build -b html -c sites/docs/ sites/docs/ sites/docs/html || die
|
|
fi
|
|
}
|
|
|
|
src_test() {
|
|
local DISTUTILS_NO_PARALLEL_BUILD=1
|
|
distutils-r1_src_test
|
|
}
|
|
|
|
python_test() {
|
|
nosetests tests || die "Tests failed under ${EPYTHON}"
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( sites/docs/html/. )
|
|
distutils-r1_python_install_all
|
|
}
|