mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-03 11:37:27 -08:00
4c2a6a6404
GitDB allows you to access bare git repositories for reading and writing. It aims at allowing full access to loose objects as well as packs with performance and scalability in mind. It operates exclusively on streams, allowing to handle large objects with a small memory footprint. The package is the successor of gitdb, where the core package name was changed to gitdb2. Bug: https://bugs.gentoo.org/620064 Closes: https://github.com/gentoo/gentoo/pull/4798 Package-Manager: Portage-2.3.5, Repoman-2.3.1
57 lines
1.2 KiB
Bash
57 lines
1.2 KiB
Bash
# Copyright 1999-2017 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=6
|
|
|
|
PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="GitDB is a pure-Python git object database"
|
|
HOMEPAGE="
|
|
https://github.com/gitpython-developers/gitdb
|
|
https://pypi.python.org/pypi/gitdb2"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="test"
|
|
|
|
RDEPEND="
|
|
!dev-python/gitdb[${PYTHON_USEDEP}]
|
|
>=dev-python/smmap2-2.0.1[${PYTHON_USEDEP}]"
|
|
DEPEND="${RDEPEND}
|
|
test? (
|
|
dev-python/nose[${PYTHON_USEDEP}]
|
|
dev-vcs/git
|
|
)"
|
|
|
|
src_test() {
|
|
local i
|
|
|
|
mkdir "${T}"/repo || die
|
|
cd "${T}"/repo || die
|
|
|
|
for (( i = 0; i < 2500; ++i )); do
|
|
echo "${i}" > file"${i}" || die
|
|
done
|
|
|
|
git init || die
|
|
git config user.email "you@example.com" || die
|
|
git config user.name "Your Name" || die
|
|
git add -A || die
|
|
git commit -q -m ".." || die
|
|
git clone --bare "${T}"/repo "${T}"/repo.git || die
|
|
cd "${S}" || die
|
|
|
|
distutils-r1_src_test
|
|
}
|
|
|
|
python_test() {
|
|
#TRAVIS=1 disables performance tests which rely on the gitdb repo
|
|
local -x TRAVIS=1
|
|
local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
|
|
nosetests -v || die "Tests fail with ${EPYTHON}"
|
|
}
|