mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-07-25 08:58:27 -07:00
6f7152946c
Package-Manager: Portage-2.3.84, Repoman-2.3.20 RepoMan-Options: --include-arches="amd64" Signed-off-by: Agostino Sarubbo <ago@gentoo.org>
44 lines
1.4 KiB
Bash
44 lines
1.4 KiB
Bash
# Copyright 1999-2020 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
|
|
|
|
inherit distutils-r1 prefix readme.gentoo-r1
|
|
|
|
DESCRIPTION="Python package for providing Mozilla's CA Bundle"
|
|
HOMEPAGE="http://certifi.io/ https://pypi.org/project/certifi"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="MPL-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
|
|
IUSE=""
|
|
|
|
RDEPEND="app-misc/ca-certificates"
|
|
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
|
|
|
|
# Do not drop this patch -- this will affect system's security
|
|
PATCHES=( "${FILESDIR}"/certifi-2018.4.16-use-system-cacerts.patch )
|
|
|
|
python_prepare_all() {
|
|
distutils-r1_python_prepare_all
|
|
|
|
eprefixify certifi/core.py
|
|
}
|
|
|
|
python_install_all() {
|
|
distutils-r1_python_install_all
|
|
|
|
local DOC_CONTENTS="
|
|
In Gentoo, we don't use certifi's bundled CA certificates.
|
|
Instead we remove bundled cacert.pem and patch certifi
|
|
to return system's CA certificates.
|
|
"
|
|
readme.gentoo_create_doc
|
|
|
|
# Precaution -- nothing should use bundled CA certificates
|
|
find "${D}" -name 'cacert.pem' -delete || die "Failed to delete bundled CA certificates"
|
|
}
|