mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
d8b09316b2
Only ebuilds which previously were happy with any slot (those which explicitly specify one of the 5.x slots are allowed to keep doing so until they have been migrated to the eclasses) and which do not require a version of Lua higher than 5.1 (to prevent CI from complaining about non-existent dependencies; all of these should have been masked or USE-masked by now anyway). Signed-off-by: Marek Szuba <marecki@gentoo.org>
90 lines
1.7 KiB
Bash
90 lines
1.7 KiB
Bash
# Copyright 1999-2020 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=6
|
|
PYTHON_COMPAT=( python3_6 )
|
|
USE_RUBY="ruby21 ruby22 ruby23 ruby24 ruby25"
|
|
DISTUTILS_OPTIONAL=1
|
|
|
|
inherit autotools distutils-r1 ruby-single
|
|
|
|
DESCRIPTION="Prelude-SIEM Framework Library"
|
|
HOMEPAGE="https://www.prelude-siem.org"
|
|
SRC_URI="https://www.prelude-siem.org/pkg/src/${PV}/${P}.tar.gz"
|
|
|
|
LICENSE="GPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="lua perl python ruby"
|
|
|
|
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
|
|
|
RDEPEND="net-libs/gnutls:=
|
|
lua? ( dev-lang/lua:0= )
|
|
perl? ( dev-lang/perl:= virtual/perl-ExtUtils-MakeMaker )
|
|
python? ( ${PYTHON_DEPS} )
|
|
ruby? ( ${RUBY_DEPS} )"
|
|
|
|
DEPEND="${RDEPEND}
|
|
>=dev-lang/swig-3.0.7
|
|
dev-util/gtk-doc-am
|
|
sys-devel/flex
|
|
virtual/pkgconfig
|
|
virtual/yacc"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}/${P}-fix-python-bindings.patch"
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# Avoid null runpaths in Perl bindings.
|
|
sed -e 's/ LD_RUN_PATH=""//' -i "${S}/bindings/Makefile.am" || die "sed failed"
|
|
|
|
eautoreconf
|
|
|
|
if use python; then
|
|
cd bindings/python || die
|
|
distutils-r1_src_prepare
|
|
fi
|
|
}
|
|
|
|
src_configure() {
|
|
local myconf=(
|
|
--enable-easy-bindings
|
|
--with-swig
|
|
--without-python2
|
|
$(use_with lua)
|
|
$(use_with perl)
|
|
$(usex perl '--with-perl-installdirs=vendor' '')
|
|
$(use_with ruby)
|
|
)
|
|
|
|
if use python; then
|
|
python_setup
|
|
myconf+=( --with-python3="${EPYTHON}" )
|
|
else
|
|
myconf+=( --without-python3 )
|
|
fi
|
|
|
|
econf "${myconf[@]}"
|
|
}
|
|
|
|
src_compile() {
|
|
default
|
|
if use python; then
|
|
cd bindings/python || die
|
|
distutils-r1_src_compile
|
|
fi
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
find "${D}" -name '*.la' -delete || die
|
|
if use python; then
|
|
cd bindings/python || die
|
|
distutils-r1_src_install
|
|
fi
|
|
}
|