Files
gentoo/dev-cpp/simpleini/simpleini-4.19.ebuild
T
Ionen Wolkens f9de5249f7 dev-cpp/simpleini: new package, add 4.19
Header-only package for games-engines/devilutionx.

Some distributions and former (treecleaned) ::guru package make it
into a shared library, but would rather not invent anything the build
system doesn't handle.

Skipping ConvertUTF.* given this is a generic header and it doesn't
make much sense to be provided by this package. Shared library would
simplify this given could build-in along with ConvertUTF.c, but it's
still possible to have ICU handle it and devilutionx currently disable
conversion altogether (can revisit as needed).

Currently also no pkg-config files nor particularly standard way to
look for it either, but simple /usr/include/SimpleIni.h is easy to
handle+unique and devilutionx finds it (it also looks for simpleini.pc
even though upstream doesn't provide it, for future use)

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
2022-07-25 19:05:47 -04:00

41 lines
1.0 KiB
Bash

# Copyright 2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic toolchain-funcs
DESCRIPTION="C++ library providing a simple API to read and write INI-style files"
HOMEPAGE="https://github.com/brofield/simpleini/"
SRC_URI="https://github.com/brofield/simpleini/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"
DEPEND="test? ( dev-cpp/gtest )"
BDEPEND="test? ( virtual/pkgconfig )"
src_compile() {
if use test; then
append-cppflags $($(tc-getPKG_CONFIG) --cflags gtest_main || die)
append-ldflags $(test-flags-CCLD -pthread)
append-libs $($(tc-getPKG_CONFIG) --libs gtest_main || die)
local emakeargs=(
{CC,CXX}="$(tc-getCXX)"
CXXFLAGS="${CXXFLAGS}"
CPPFLAGS="${CPPFLAGS}"
LDFLAGS="${LDFLAGS} ${LIBS}"
)
emake -C tests "${emakeargs[@]}"
fi
}
src_install() {
# note: skipping ConvertUTF, can use -DSI_CONVERT_ICU instead if needed
doheader SimpleIni.h
einstalldocs
}