mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-06-25 11:08:08 -07:00
3477d1d0ee
entry_points are empty, therefore setuptools is not a runtime dependency. Closes: https://bugs.gentoo.org/745606 Package-Manager: Portage-3.0.8, Repoman-3.0.1 Signed-off-by: Louis Sautier <sbraz@gentoo.org>
51 lines
1.2 KiB
Bash
51 lines
1.2 KiB
Bash
# Copyright 1999-2020 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( python3_{6..9} pypy3 )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_P="path-${PV}"
|
|
|
|
DESCRIPTION="A module wrapper for os.path"
|
|
HOMEPAGE="https://pypi.org/project/path/ https://github.com/jaraco/path"
|
|
SRC_URI="mirror://pypi/p/path/${MY_P}.tar.gz"
|
|
S="${WORKDIR}/${MY_P}"
|
|
|
|
SLOT="0"
|
|
LICENSE="MIT"
|
|
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 sparc x86 ~amd64-linux ~x86-linux"
|
|
|
|
RDEPEND="
|
|
dev-python/appdirs[${PYTHON_USEDEP}]
|
|
!<dev-python/pytest-shutil-1.7.0-r1
|
|
!<dev-python/pytest-virtualenv-1.7.0-r1"
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/packaging[${PYTHON_USEDEP}]
|
|
dev-python/pytest[${PYTHON_USEDEP}]
|
|
)"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_prepare_all() {
|
|
# avoid a setuptools_scm dependency
|
|
sed -e "s/setup_requires = setuptools_scm/version = '${PV}'/" \
|
|
-i setup.cfg || die
|
|
|
|
# disable fancy test deps
|
|
sed -e 's: --flake8:: ; s: --black:: ; s: --cov:: ; s: --mypy::' \
|
|
-i pytest.ini || die
|
|
|
|
# fragile test for import time
|
|
sed -i -e 's:test_import_time:_&:' test_path.py || die
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_test() {
|
|
PYTHONPATH=. pytest -vv || die
|
|
}
|