mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-06 00:48:18 -07:00
ce614bd79d
Restrict the test dependency on dev-python/python-xmp-toolkit to little endian platforms. According to upstream, media-libs/exempi is broken on big endian anyway. Remove the dep entirely for older versions where we don't care about testing anymore. Signed-off-by: Michał Górny <mgorny@gentoo.org>
68 lines
1.7 KiB
Bash
68 lines
1.7 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_EXT=1
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{10..12} pypy3 )
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="Python library to work with pdf files based on qpdf"
|
|
HOMEPAGE="
|
|
https://github.com/pikepdf/pikepdf/
|
|
https://pypi.org/project/pikepdf/
|
|
"
|
|
|
|
LICENSE="MPL-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~ppc ppc64 ~riscv ~s390 sparc x86"
|
|
|
|
# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
|
|
# https://qpdf.readthedocs.io/en/stable/release-notes.html.
|
|
DEPEND="
|
|
>=app-text/qpdf-11.5.0:0=
|
|
"
|
|
RDEPEND="
|
|
${DEPEND}
|
|
dev-python/deprecated[${PYTHON_USEDEP}]
|
|
>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
|
|
dev-python/packaging[${PYTHON_USEDEP}]
|
|
>=dev-python/pillow-10.0.1[lcms,${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
>=dev-python/pybind11-2.10.1[${PYTHON_USEDEP}]
|
|
>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
|
|
test? (
|
|
>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
|
|
>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
|
|
>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
|
|
>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
|
|
>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
|
|
>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
|
|
>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
|
|
$(python_gen_cond_dep '
|
|
dev-python/tomli[${PYTHON_USEDEP}]
|
|
' 3.10)
|
|
media-libs/tiff[zlib]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
EPYTEST_DESELECT=(
|
|
# fragile to system load
|
|
tests/test_image_access.py::test_random_image
|
|
)
|
|
|
|
src_prepare() {
|
|
sed -e '/-n auto/d' -i pyproject.toml || die
|
|
distutils-r1_src_prepare
|
|
}
|
|
|
|
python_test() {
|
|
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
|
|
epytest -p timeout
|
|
}
|