mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-23 20:07:28 -08:00
c5455e9e02
* Excluding xorg.freedesktop.org * Excluding tango.freedesktop.org The following modified ebuilds were found to have problems after modification but the problems were determined to not be a regression. Upstream tarball has a new hash: * app-misc/evtest-1.29 * app-misc/evtest-1.30 * dev-embedded/scratchbox2-2.0-r1 * dev-ml/cairo-ocaml-1.2.0 * net-libs/libqmi-1.0.0 * sys-auth/libfprint-0.4.0 * sys-auth/libfprint-0.5.0 * sys-auth/libfprint-0.5.1 Upstream tarball has been deleted: * dev-libs/liblazy-0.2 * dev-util/pkgconfig-openbsd-20130507-r1 * x11-libs/xvba-video-0.8.0-r3 * x11-misc/driconf-0.9.1-r1 * x11-misc/xdg-utils-1.1.0_rc2-r1
90 lines
2.2 KiB
Bash
90 lines
2.2 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
|
|
PYTHON_REQ_USE="threads(+)"
|
|
|
|
inherit autotools eutils python-r1
|
|
|
|
DESCRIPTION="Python bindings for the D-Bus messagebus"
|
|
HOMEPAGE="https://www.freedesktop.org/wiki/Software/DBusBindings https://dbus.freedesktop.org/doc/dbus-python/"
|
|
SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~m68k-mint"
|
|
IUSE="doc examples test"
|
|
# API docs generated with epydoc, which is python2-only
|
|
REQUIRED_USE="
|
|
${PYTHON_REQUIRED_USE}
|
|
doc? ( python_targets_python2_7 )"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/dbus-glib-0.100:=
|
|
>=sys-apps/dbus-1.6:=
|
|
${PYTHON_DEPS}"
|
|
DEPEND="${RDEPEND}
|
|
virtual/pkgconfig
|
|
doc? (
|
|
dev-python/docutils[python_targets_python2_7?]
|
|
=dev-python/epydoc-3*[python_targets_python2_7?] )
|
|
test? ( dev-python/pygobject:3[${PYTHON_USEDEP}] )"
|
|
|
|
src_prepare() {
|
|
# Update py-compile, bug 529502.
|
|
eautoreconf
|
|
python_copy_sources
|
|
}
|
|
|
|
src_configure() {
|
|
configuring() {
|
|
local PYTHON_CONFIG
|
|
python_export PYTHON_CONFIG
|
|
|
|
# epydoc is python2-only, bug #447642
|
|
local apidocs=--disable-api-docs
|
|
[[ ${EPYTHON/.*} = "python2" ]] && apidocs=$(use_enable doc api-docs)
|
|
|
|
econf \
|
|
--docdir="${EPREFIX}"/usr/share/doc/${PF} \
|
|
--disable-html-docs \
|
|
${apidocs} \
|
|
PYTHON_INCLUDES="$(${PYTHON_CONFIG} --includes)" \
|
|
PYTHON_LIBS="$(${PYTHON_CONFIG} --ldflags)"
|
|
# configure assumes that ${PYTHON}-config executable exists :/
|
|
}
|
|
python_foreach_impl run_in_build_dir configuring
|
|
}
|
|
|
|
src_compile() {
|
|
python_foreach_impl run_in_build_dir default
|
|
}
|
|
|
|
src_test() {
|
|
unset DBUS_SESSION_BUS_ADDRESS
|
|
python_foreach_impl run_in_build_dir default
|
|
}
|
|
|
|
src_install() {
|
|
installing() {
|
|
default
|
|
[[ ${EPYTHON/.*} = "python2" ]] && use doc && dohtml -r api/*
|
|
}
|
|
python_foreach_impl run_in_build_dir installing
|
|
prune_libtool_files --modules
|
|
|
|
if use examples; then
|
|
insinto /usr/share/doc/${PF}
|
|
doins -r examples
|
|
fi
|
|
}
|
|
|
|
run_in_build_dir() {
|
|
pushd "${BUILD_DIR}" > /dev/null || die
|
|
"$@"
|
|
popd > /dev/null
|
|
}
|