mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-07-24 08:38:07 -07:00
d9fb326341
Package-Manager: Portage-2.3.89, Repoman-2.3.20 RepoMan-Options: --include-arches="x86" Signed-off-by: Agostino Sarubbo <ago@gentoo.org>
48 lines
1.1 KiB
Bash
48 lines
1.1 KiB
Bash
# Copyright 1999-2020 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI="6"
|
|
|
|
PYTHON_COMPAT=( python3_{6,7} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Package used for parsing and generating iCalendar files (RFC 2445)"
|
|
HOMEPAGE="https://github.com/collective/icalendar"
|
|
SRC_URI="mirror://pypi/i/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 ~arm ~arm64 x86"
|
|
IUSE="doc test"
|
|
RESTRICT="!test? ( test )"
|
|
DOCS=( "README.rst" )
|
|
|
|
RDEPEND="
|
|
dev-python/python-dateutil[${PYTHON_USEDEP}]
|
|
dev-python/pytz[${PYTHON_USEDEP}]
|
|
dev-python/setuptools[${PYTHON_USEDEP}]"
|
|
|
|
DEPEND="
|
|
${RDEPEND}
|
|
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
|
|
test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
|
|
|
|
python_prepare_all() {
|
|
# reset conf.py to not read version from an installed instance
|
|
sed -e "s:pkg_resources.get_distribution('icalendar').version:'${PV}':" \
|
|
-i docs/conf.py || die
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
if use doc; then
|
|
emake -C docs html
|
|
HTML_DOCS=( docs/_build/html/. )
|
|
fi
|
|
}
|
|
|
|
python_test() {
|
|
pytest -vv src/icalendar || die "test failed under ${EPYTHON}"
|
|
}
|