mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-26 21:07:30 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
71 lines
1.5 KiB
Bash
71 lines
1.5 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
|
|
|
|
inherit python-r1 qmake-utils
|
|
|
|
MY_P=QScintilla-gpl-${PV}
|
|
|
|
DESCRIPTION="Python bindings for Qscintilla"
|
|
HOMEPAGE="http://www.riverbankcomputing.com/software/qscintilla/intro"
|
|
SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
|
|
|
|
LICENSE="|| ( GPL-2 GPL-3 )"
|
|
SLOT="0"
|
|
KEYWORDS="alpha amd64 ia64 ppc ppc64 ~sparc x86"
|
|
IUSE="debug"
|
|
|
|
DEPEND="
|
|
${PYTHON_DEPS}
|
|
>=dev-python/sip-4.16:=[${PYTHON_USEDEP}]
|
|
>=dev-python/PyQt4-4.11[X,${PYTHON_USEDEP}]
|
|
dev-qt/qtcore:4
|
|
dev-qt/qtgui:4
|
|
~x11-libs/qscintilla-${PV}:=
|
|
"
|
|
RDEPEND="${DEPEND}"
|
|
|
|
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
|
|
|
S=${WORKDIR}/${MY_P}/Python
|
|
|
|
src_prepare() {
|
|
python_copy_sources
|
|
}
|
|
|
|
src_configure() {
|
|
configuration() {
|
|
local myconf=(
|
|
"${PYTHON}" configure.py
|
|
--destdir="$(python_get_sitedir)"/PyQt4
|
|
--sip-incdir="$(python_get_includedir)"
|
|
--pyqt-sipdir="${EPREFIX}"/usr/share/sip
|
|
--qsci-sipdir="${EPREFIX}"/usr/share/sip
|
|
--pyqt=PyQt4
|
|
--no-timestamp
|
|
$(use debug && echo --debug)
|
|
)
|
|
echo "${myconf[@]}"
|
|
"${myconf[@]}" || die
|
|
|
|
# Run eqmake4 to respect toolchain, build flags, and prevent stripping
|
|
eqmake4
|
|
}
|
|
python_foreach_impl run_in_build_dir configuration
|
|
}
|
|
|
|
src_compile() {
|
|
python_foreach_impl run_in_build_dir default
|
|
}
|
|
|
|
src_install() {
|
|
installation() {
|
|
emake INSTALL_ROOT="${D}" install
|
|
python_optimize
|
|
}
|
|
python_foreach_impl run_in_build_dir installation
|
|
}
|