mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-28 21:47:28 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
71 lines
1.8 KiB
Bash
71 lines
1.8 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
|
|
|
|
inherit distutils-r1 vcs-snapshot
|
|
|
|
DESCRIPTION="library and command line tool to visualise the flow of Python applications"
|
|
HOMEPAGE="http://pycallgraph.slowchop.com/"
|
|
SRC_URI="https://github.com/gak/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="GPL-2"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
IUSE="doc examples test"
|
|
|
|
CDEPEND="media-gfx/graphviz"
|
|
DEPEND="
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
dev-python/sphinx[${PYTHON_USEDEP}]
|
|
doc? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
|
|
examples? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
|
|
test? (
|
|
${CDEPEND}
|
|
dev-python/pytest[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
RDEPEND="${CDEPEND}"
|
|
|
|
python_prepare_all() {
|
|
local PATCHES=(
|
|
"${FILESDIR}"/python3.3-tests.patch
|
|
)
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
if use examples; then
|
|
cd docs/examples || die "Couldn't change to docs/examples"
|
|
"${PYTHON}" generate.py || die "Couldn't generate examples"
|
|
cd - || die "Couldn't return to previous directory"
|
|
|
|
cd docs/guide/filtering || die "Couldn't change to docs/guide/filtering"
|
|
"${PYTHON}" generate.py || die "Couldn't generate filtering examples"
|
|
cd - || die "Couldn't return to previous directory"
|
|
fi
|
|
|
|
use doc && emake -C docs html
|
|
|
|
emake -C docs man
|
|
}
|
|
|
|
python_test() {
|
|
# gephi is not in portage; thus, skip the gephi tests
|
|
rm -f test/test_gephi.py || die "Couldn't remove gephi tests"
|
|
|
|
py.test --ignore=pycallgraph/memory_profiler.py test pycallgraph examples || die "Tests failed under ${EPYTHON}"
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( docs/_build/html/. )
|
|
use examples && local EXAMPLES=( examples/. )
|
|
|
|
distutils-r1_python_install_all
|
|
|
|
doman docs/_build/man/pycallgraph.1
|
|
}
|