mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-28 09:37:29 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
92 lines
1.9 KiB
Bash
92 lines
1.9 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
|
|
|
|
inherit check-reqs toolchain-funcs python-r1
|
|
|
|
if [[ ${PV} == "9999" ]] ; then
|
|
EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
|
|
inherit autotools git-r3
|
|
else
|
|
SRC_URI="http://downloads.skewed.de/${PN}/${P}.tar.bz2"
|
|
KEYWORDS="~amd64 ~x86"
|
|
fi
|
|
|
|
DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
|
|
HOMEPAGE="http://graph-tool.skewed.de/"
|
|
|
|
LICENSE="GPL-3"
|
|
SLOT="0"
|
|
IUSE="+cairo openmp"
|
|
|
|
CDEPEND="${PYTHON_DEPS}
|
|
>=dev-libs/boost-1.54.0[python,${PYTHON_USEDEP}]
|
|
dev-libs/expat
|
|
dev-python/numpy[${PYTHON_USEDEP}]
|
|
sci-libs/scipy[${PYTHON_USEDEP}]
|
|
>=sci-mathematics/cgal-3.5
|
|
cairo? (
|
|
dev-cpp/cairomm
|
|
dev-python/pycairo[${PYTHON_USEDEP}]
|
|
)"
|
|
RDEPEND="${CDEPEND}
|
|
dev-python/matplotlib[${PYTHON_USEDEP}]"
|
|
DEPEND="${CDEPEND}
|
|
dev-cpp/sparsehash
|
|
virtual/pkgconfig"
|
|
|
|
# most machines don't have enough ram for parallel builds
|
|
MAKEOPTS="${MAKEOPTS} -j1"
|
|
|
|
# bug 453544
|
|
CHECKREQS_DISK_BUILD="6G"
|
|
|
|
pkg_pretend() {
|
|
if use openmp ; then
|
|
tc-has-openmp || die "Please switch to an openmp compatible compiler"
|
|
fi
|
|
check-reqs_pkg_pretend
|
|
}
|
|
|
|
src_prepare() {
|
|
[[ ${PV} == "9999" ]] && eautoreconf
|
|
>py-compile
|
|
python_copy_sources
|
|
}
|
|
|
|
src_configure() {
|
|
local threads
|
|
has_version dev-libs/boost[threads] && threads="-mt"
|
|
|
|
configure() {
|
|
econf \
|
|
--disable-static \
|
|
--disable-optimization \
|
|
$(use_enable openmp) \
|
|
$(use_enable cairo) \
|
|
--with-boost-python="${EPYTHON: -3}${threads}"
|
|
}
|
|
python_foreach_impl run_in_build_dir configure
|
|
}
|
|
|
|
src_compile() {
|
|
python_foreach_impl run_in_build_dir default
|
|
}
|
|
|
|
src_install() {
|
|
python_foreach_impl run_in_build_dir default
|
|
prune_libtool_files --modules
|
|
|
|
# remove unwanted extra docs
|
|
rm -r "${ED}"/usr/share/doc/${PN} || die
|
|
}
|
|
|
|
run_in_build_dir() {
|
|
pushd "${BUILD_DIR}" > /dev/null
|
|
"$@"
|
|
popd > /dev/null
|
|
}
|