mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-06 17:47:07 -08:00
Agostino Sarubbo
84d240f545
Package-Manager: Portage-2.3.84, Repoman-2.3.20 RepoMan-Options: --include-arches="x86" Signed-off-by: Agostino Sarubbo <ago@gentoo.org>
61 lines
1.3 KiB
Bash
61 lines
1.3 KiB
Bash
# Copyright 1999-2020 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7,8}} )
|
|
|
|
inherit distutils-r1
|
|
|
|
if [[ ${PV} == 9999 ]]; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://github.com/tqdm/tqdm"
|
|
else
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
KEYWORDS="amd64 ~hppa ~sparc x86"
|
|
fi
|
|
|
|
DESCRIPTION="Add a progress meter to your loops in a second"
|
|
HOMEPAGE="https://github.com/tqdm/tqdm"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
IUSE="examples"
|
|
|
|
RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
|
|
BDEPEND="${RDEPEND}"
|
|
|
|
distutils_enable_tests nose
|
|
|
|
python_prepare_all() {
|
|
sed -r \
|
|
-e "s:'nose'(,[[:space:]]*|)::" \
|
|
-e "s:'flake8'(,[[:space:]]*|)::" \
|
|
-e "s:'coverage'(,[[:space:]]*|)::" \
|
|
-i setup.py
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_test() {
|
|
# tests_main.py requires the package to be installed
|
|
distutils_install_for_testing
|
|
# Skip unpredictable performance tests
|
|
nosetests tqdm -v --ignore 'tests_perf.py' \
|
|
|| die "tests failed with ${EPYTHON}"
|
|
}
|
|
|
|
python_install() {
|
|
doman "${BUILD_DIR}"/lib/tqdm/tqdm.1
|
|
rm "${BUILD_DIR}"/lib/tqdm/tqdm.1 || die
|
|
distutils-r1_python_install --skip-build
|
|
}
|
|
|
|
python_install_all() {
|
|
if use examples; then
|
|
dodoc -r examples
|
|
docompress -x /usr/share/doc/${PF}/examples
|
|
fi
|
|
distutils-r1_python_install_all
|
|
}
|