mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-30 04:47:28 -07:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
70 lines
1.8 KiB
Bash
70 lines
1.8 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
# test phase is pointless since it errors in circa 60% of 1984 tests
|
|
RESTRICT="test"
|
|
|
|
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="NumPy aware dynamic Python compiler using LLVM"
|
|
HOMEPAGE="http://numba.pydata.org/"
|
|
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
|
|
IUSE="doc examples test"
|
|
|
|
RDEPEND="
|
|
dev-python/llvmlite[${PYTHON_USEDEP}]
|
|
>=dev-python/numpy-1.6[${PYTHON_USEDEP}]
|
|
$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python{2_7,3_3})
|
|
$(python_gen_cond_dep 'dev-python/funcsigs[${PYTHON_USEDEP}]' python2_7)"
|
|
DEPEND="test? ( ${RDEPEND} )
|
|
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
|
|
|
|
# Delete intersphinx & entry to set sphinxjp.themecore, which is absent from portage, from conf.py
|
|
PATCHES=( "${FILESDIR}"/${PN}-0.19.2-docbuild.patch )
|
|
|
|
python_prepare_all() {
|
|
# Re-set them of doc build to one provided by sphinx
|
|
if has_version ">=dev-python/sphinx-1.3.1"; then
|
|
sed -e 's:basicstrap:classic:' -i docs/source/conf.py || die
|
|
else
|
|
sed -e 's:basicstrap:default:' -i docs/source/conf.py || die
|
|
fi
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile() {
|
|
if ! python_is_python3; then
|
|
local CFLAGS="${CFLAGS} -fno-strict-aliasing"
|
|
export CFLAGS
|
|
fi
|
|
distutils-r1_python_compile
|
|
}
|
|
|
|
python_compile_all() {
|
|
use doc && emake -C docs/ html
|
|
}
|
|
|
|
python_test() {
|
|
cd "${BUILD_DIR}"/lib* || die
|
|
${PYTHON} -c "import numba; numba.test()" || die
|
|
}
|
|
|
|
python_install_all() {
|
|
# doc needs obsolete sphinxjp package
|
|
# use doc && dodoc docs/Numba.pdf
|
|
use examples && local EXAMPLES=( examples/. )
|
|
use doc && local HTML_DOCS=( docs/_build/html/. )
|
|
|
|
distutils-r1_python_install_all
|
|
}
|