mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-30 04:47:28 -07:00
58 lines
1.5 KiB
Bash
58 lines
1.5 KiB
Bash
# Copyright 2020-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=hatchling
|
|
PYTHON_COMPAT=( python3_{10..13} pypy3 )
|
|
|
|
inherit distutils-r1 optfeature pypi
|
|
|
|
DESCRIPTION="The uncompromising Python code formatter"
|
|
HOMEPAGE="
|
|
https://black.readthedocs.io/en/stable/
|
|
https://github.com/psf/black/
|
|
https://pypi.org/project/black/
|
|
"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
|
|
|
|
RDEPEND="
|
|
>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
|
|
>=dev-python/mypy-extensions-0.4.3[${PYTHON_USEDEP}]
|
|
>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
|
|
>=dev-python/pathspec-0.9.0[${PYTHON_USEDEP}]
|
|
>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
|
|
$(python_gen_cond_dep '
|
|
>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
|
|
>=dev-python/typing-extensions-4.0.1[${PYTHON_USEDEP}]
|
|
' 3.10)
|
|
"
|
|
BDEPEND="
|
|
dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
|
|
dev-python/hatch-vcs[${PYTHON_USEDEP}]
|
|
test? (
|
|
>=dev-python/aiohttp-3.10[${PYTHON_USEDEP}]
|
|
dev-python/aiohttp-cors[${PYTHON_USEDEP}]
|
|
dev-python/colorama[${PYTHON_USEDEP}]
|
|
dev-python/parameterized[${PYTHON_USEDEP}]
|
|
dev-python/pytest-forked[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
|
|
# pytest-forked to workaround fd leakage in blackd
|
|
# https://github.com/psf/black/issues/4504
|
|
epytest -p pytest_forked --forked
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature "blackd - HTTP API for black" \
|
|
"dev-python/aiohttp dev-python/aiohttp-cors"
|
|
}
|