Files
gentoo/kde-frameworks/kdesignerplugin/kdesignerplugin-5.50.0.ebuild
T
Mikle Kolyada b33fa8eaeb kde-frameworks/kdesignerplugin: amd64 stable wrt bug #667760
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11
2018-10-10 14:58:07 +03:00

55 lines
1.4 KiB
Bash

# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
KDE_HANDBOOK="optional"
KDE_QTHELP="false"
KDE_TEST="false"
inherit kde5
DESCRIPTION="Framework providing plugins to use KDE frameworks widgets in QtDesigner"
LICENSE="LGPL-2.1+"
KEYWORDS="amd64 ~arm ~arm64 x86"
IUSE="designer nls webkit"
RDEPEND="
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kcoreaddons)
designer? (
$(add_qt_dep designer)
$(add_frameworks_dep kcompletion)
$(add_frameworks_dep kconfigwidgets)
$(add_frameworks_dep kiconthemes)
$(add_frameworks_dep kio)
$(add_frameworks_dep kitemviews)
$(add_frameworks_dep kplotting)
$(add_frameworks_dep ktextwidgets)
$(add_frameworks_dep kwidgetsaddons)
$(add_frameworks_dep kxmlgui)
$(add_frameworks_dep sonnet)
)
webkit? (
$(add_qt_dep designer)
$(add_qt_dep qtgui)
$(add_frameworks_dep kdewebkit)
)
"
DEPEND="${RDEPEND}
nls? ( $(add_qt_dep linguist-tools) )
"
src_configure() {
local mycmakeargs=(
$(cmake-utils_use_find_package designer KF5IconThemes)
$(cmake-utils_use_find_package designer KF5ItemViews)
$(cmake-utils_use_find_package designer KF5KIO)
$(cmake-utils_use_find_package designer KF5Plotting)
$(cmake-utils_use_find_package designer KF5TextWidgets)
$(cmake-utils_use_find_package designer KF5WidgetsAddons)
$(cmake-utils_use_find_package webkit KF5WebKit)
)
kde5_src_configure
}