Files
gentoo/sys-apps/pkgcore/pkgcore-0.10.13-r1.ebuild
T
Sam James c6c58a4317 sys-apps/pkgcore: ~x64-macos keyworded
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>
2020-11-28 07:38:31 +00:00

52 lines
1.1 KiB
Bash

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python3_{6..9} )
DISTUTILS_IN_SOURCE_BUILD=1
inherit distutils-r1
if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://github.com/pkgcore/pkgcore.git"
inherit git-r3
else
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 ~s390 sparc x86 ~x64-macos"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
fi
DESCRIPTION="a framework for package management"
HOMEPAGE="https://github.com/pkgcore/pkgcore"
LICENSE="BSD MIT"
SLOT="0"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="dev-python/lxml[${PYTHON_USEDEP}]"
if [[ ${PV} == *9999 ]]; then
RDEPEND+=" ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]"
else
RDEPEND+=" >=dev-python/snakeoil-0.8.7[${PYTHON_USEDEP}]"
fi
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
dev-python/pytest[${PYTHON_USEDEP}]
dev-vcs/git
)
"
PATCHES=(
"${FILESDIR}/${P}-metadata-xsd.patch"
)
python_test() {
esetup.py test
}
python_install_all() {
local DOCS=( AUTHORS NEWS.rst )
[[ ${PV} == *9999 ]] || doman man/*
distutils-r1_python_install_all
}