mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-28 04:07:32 -07:00
8ae275e06a
stable wrt bug #734032 Package-Manager: Portage-3.0.1, Repoman-2.3.23 RepoMan-Options: --include-arches="ppc" Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
55 lines
1.4 KiB
Bash
55 lines
1.4 KiB
Bash
# Copyright 1999-2020 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( python3_{6..9} )
|
|
DISTUTILS_USE_SETUPTOOLS=rdepend
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Cheroot is the high-performance, pure-Python HTTP server used by CherryPy."
|
|
HOMEPAGE="https://cherrypy.org/ https://pypi.org/project/Cheroot/ https://github.com/cherrypy/cheroot"
|
|
SRC_URI="mirror://pypi/C/${PN/c/C}/${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm arm64 ~ia64 ppc ~ppc64 x86"
|
|
|
|
RDEPEND="
|
|
>=dev-python/six-1.11.0[${PYTHON_USEDEP}]
|
|
>=dev-python/more-itertools-2.6[${PYTHON_USEDEP}]
|
|
dev-python/jaraco-functools[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
${RDEPEND}
|
|
dev-python/jaraco-text[${PYTHON_USEDEP}]
|
|
>=dev-python/pytest-mock-1.11.0[${PYTHON_USEDEP}]
|
|
dev-python/pyopenssl[${PYTHON_USEDEP}]
|
|
dev-python/requests-unixsocket[${PYTHON_USEDEP}]
|
|
dev-python/trustme[${PYTHON_USEDEP}]
|
|
dev-python/urllib3[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/cheroot-8.3.0-test-unixsocket.patch
|
|
)
|
|
|
|
python_prepare_all() {
|
|
sed -e "s/use_scm_version=True/version='${PV}'/" -i setup.py || die
|
|
sed -e '/setuptools_scm/d' -i setup.cfg || die
|
|
sed -e '/--cov/d' \
|
|
-e '/--testmon/d' \
|
|
-e '/--numproc/d' \
|
|
-i pytest.ini || die
|
|
|
|
# broken
|
|
sed -e '/False.*localhost/d' \
|
|
-i cheroot/test/test_ssl.py || die
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|