mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 02:17:34 -08:00
229b7fbb63
It had a Modern C warning because the ancient standard routines failed to detect that STDC_HEADERS could be safely set: ``` checking for ANSI C header files... no ``` Fortunately the code never relied on this anyway, so it was a moot point. But a noisy one. Autoconf 2.53 is pretty long in the tooth so take this opportunity to freshen up, anyway. Closes: https://bugs.gentoo.org/908576 Signed-off-by: Eli Schwartz <eschwartz93@gmail.com> Signed-off-by: Sam James <sam@gentoo.org>
81 lines
1.6 KiB
Bash
81 lines
1.6 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit autotools
|
|
|
|
MY_P=${PN}${PV//.}
|
|
|
|
DESCRIPTION="Mother Board Monitor Program for X Window System"
|
|
HOMEPAGE="http://www.nt.phys.kyushu-u.ac.jp/shimizu/download/download.html"
|
|
SRC_URI="http://www.nt.phys.kyushu-u.ac.jp/shimizu/download/xmbmon/${MY_P}.tar.gz"
|
|
# http://www.nt.phys.kyushu-u.ac.jp/shimizu/download/xmbmon/${MY_P}_A7N8X-VM.patch
|
|
S="${WORKDIR}"/${MY_P}
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 x86"
|
|
IUSE="gui"
|
|
|
|
RDEPEND="
|
|
gui? (
|
|
x11-libs/libXt
|
|
x11-libs/libSM
|
|
x11-libs/libX11
|
|
x11-libs/libICE
|
|
)
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
|
|
PATCHES=(
|
|
# "${DISTDIR}"/${MY_P}_A7N8X-VM.patch
|
|
"${FILESDIR}"/${P}-fflush.patch
|
|
"${FILESDIR}"/${P}-amd64.patch
|
|
"${FILESDIR}"/${P}-pid.patch
|
|
"${FILESDIR}"/${P}-loopback.patch
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
sed -i \
|
|
-e "/^CFLAGS=/s/-O3/${CFLAGS}/" \
|
|
-e '/^LDFLAGS=-s$/d' \
|
|
Makefile.in || die
|
|
sed -i \
|
|
-e '/^[[:space:]]*CC=gcc/s,.*,:;,' \
|
|
configure.in || die
|
|
|
|
eautoreconf
|
|
}
|
|
|
|
src_compile() {
|
|
emake mbmon
|
|
use gui && emake xmbmon
|
|
}
|
|
|
|
src_install() {
|
|
dosbin mbmon
|
|
doman mbmon.1
|
|
dodoc ChangeLog* ReadMe* mbmon-rrd.pl
|
|
|
|
if use gui; then
|
|
dosbin xmbmon
|
|
doman xmbmon.1x
|
|
|
|
insinto /etc/X11/app-defaults/
|
|
newins xmbmon.resources XMBmon
|
|
fi
|
|
|
|
newinitd "${FILESDIR}"/mbmon.rc mbmon
|
|
newconfd "${FILESDIR}"/mbmon.confd mbmon
|
|
}
|
|
|
|
pkg_postinst() {
|
|
einfo "These programs access SMBus/ISA-IO ports without any kind"
|
|
einfo "of checking. It is, therefore, very dangerous and may cause"
|
|
einfo "a system-crash. Make sure you read ReadMe,"
|
|
einfo "section 4, 'How to use!'"
|
|
}
|