mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 17:09:10 -07:00
9d424f80f8
Package-Manager: Portage-3.0.20, Repoman-3.0.3 RepoMan-Options: --include-arches="x86" Signed-off-by: Agostino Sarubbo <ago@gentoo.org>
54 lines
1.3 KiB
Bash
54 lines
1.3 KiB
Bash
# Copyright 1999-2021 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
CMAKE_ECLASS=cmake
|
|
inherit cmake-multilib
|
|
|
|
DESCRIPTION="Library implementing the SSH2 protocol"
|
|
HOMEPAGE="https://www.libssh2.org"
|
|
SRC_URI="https://www.libssh2.org/download/${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
|
|
IUSE="gcrypt mbedtls zlib"
|
|
REQUIRED_USE="?? ( gcrypt mbedtls )"
|
|
# Tests try to set containers up using docker (and fail for some reason).
|
|
RESTRICT="test"
|
|
|
|
RDEPEND="
|
|
gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
|
|
!gcrypt? (
|
|
mbedtls? ( net-libs/mbedtls:0=[${MULTILIB_USEDEP}] )
|
|
!mbedtls? (
|
|
>=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}]
|
|
)
|
|
)
|
|
zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
|
|
"
|
|
DEPEND="
|
|
${RDEPEND}
|
|
"
|
|
|
|
multilib_src_configure() {
|
|
local crypto_backend=OpenSSL
|
|
if use gcrypt; then
|
|
crypto_backend=Libgcrypt
|
|
elif use mbedtls; then
|
|
crypto_backend=mbedTLS
|
|
fi
|
|
|
|
local mycmakeargs=(
|
|
-DBUILD_SHARED_LIBS=ON
|
|
-DCRYPTO_BACKEND=${crypto_backend}
|
|
-DENABLE_ZLIB_COMPRESSION=$(usex zlib)
|
|
)
|
|
cmake_src_configure
|
|
}
|
|
|
|
multilib_src_install_all() {
|
|
einstalldocs
|
|
find "${ED}" -name '*.la' -delete || die
|
|
}
|