Files
gentoo/app-forensics/chkrootkit/chkrootkit-0.55.ebuild
T
Jory Pratt 07737b95af app-forensics/chkrootkit: Fix missing includes for musl
Closes: https://bugs.gentoo.org/show_bug.cgi?id=715552
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Jory Pratt <anarchy@gentoo.org>
2022-01-02 22:00:51 -06:00

61 lines
1.4 KiB
Bash

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
GENTOO_PATCH="${PN}-0.55-gentoo.patch"
DESCRIPTION="Tool to locally check for signs of a rootkit"
HOMEPAGE="http://www.chkrootkit.org/"
SRC_URI="ftp://ftp.pangeia.com.br/pub/seg/pac/${P}.tar.gz"
SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${GENTOO_PATCH}.bz2"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86"
IUSE="+cron"
RDEPEND="cron? ( virtual/cron )"
PATCHES=(
"${WORKDIR}/${GENTOO_PATCH}"
"${FILESDIR}/${P}-fcntl_h.patch"
"${FILESDIR}/${P}-limits_h.patch"
)
src_prepare() {
default
sed -e 's:/var/adm/:/var/log/:g' \
-i chklastlog.c || die
}
src_compile() {
emake CC="$(tc-getCC)" STRIP=true sense
}
src_install() {
dosbin chkdirs chklastlog chkproc chkrootkit chkwtmp chkutmp ifpromisc strings-static
dodoc ACKNOWLEDGMENTS README*
if use cron ; then
exeinto /etc/cron.weekly
newexe "${FILESDIR}"/${PN}.cron ${PN}
fi
}
pkg_postinst() {
if use cron ; then
elog
elog "Edit /etc/cron.weekly/chkrootkit to activate chkrootkit!"
elog
fi
elog
elog "Some applications, such as portsentry, will cause chkrootkit"
elog "to produce false positives. Read the chkrootkit FAQ at"
elog "http://www.chkrootkit.org/ for more information."
elog
}