mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-23 18:38:08 -07:00
67c364b23c
Closes: https://bugs.gentoo.org/775077 Closes: https://bugs.gentoo.org/726864 Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr> Signed-off-by: Michał Górny <mgorny@gentoo.org>
44 lines
1.1 KiB
Bash
44 lines
1.1 KiB
Bash
# Copyright 1999-2021 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( python3_{7..10} pypy3 )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Measures number of Terminal column cells of wide-character codes"
|
|
HOMEPAGE="https://pypi.org/project/wcwidth/ https://github.com/jquast/wcwidth"
|
|
SRC_URI="
|
|
https://github.com/jquast/wcwidth/archive/${PV}.tar.gz
|
|
-> ${P}.gh.tar.gz"
|
|
|
|
SLOT="0"
|
|
LICENSE="MIT"
|
|
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux"
|
|
|
|
RDEPEND="
|
|
$(python_gen_cond_dep '
|
|
dev-python/backports-functools-lru-cache[${PYTHON_USEDEP}]
|
|
' -2)"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
src_prepare() {
|
|
sed -e 's:--cov-append::' \
|
|
-e 's:--cov-report=html::' \
|
|
-e 's:--cov=wcwidth::' \
|
|
-i tox.ini || die
|
|
sed -i -e 's:test_package_version:_&:' tests/test_core.py || die
|
|
|
|
# causes pytest to fail, bug 775077
|
|
sed -i '/^looponfailroots =/d' tox.ini || die
|
|
distutils-r1_src_prepare
|
|
}
|
|
|
|
python_install_all() {
|
|
docinto docs
|
|
dodoc docs/intro.rst
|
|
distutils-r1_python_install_all
|
|
}
|