mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-23 18:38:08 -07:00
2e19580ada
The LUA_USEDEP bit is sufficient to pull in a version migrated to Lua eclasses, regardless of whether either of these gets updated to a new release before we unmask slotted Lua or not. Package-Manager: Portage-3.0.9, Repoman-3.0.2 Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
56 lines
967 B
Bash
56 lines
967 B
Bash
# Copyright 1999-2020 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
LUA_COMPAT=( lua5-{1..3} luajit )
|
|
|
|
inherit lua toolchain-funcs
|
|
|
|
DESCRIPTION="Assertion library for Lua"
|
|
HOMEPAGE="http://olivinelabs.com/busted/"
|
|
SRC_URI="https://github.com/Olivine-Labs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
|
|
IUSE="test"
|
|
REQUIRED_USE="${LUA_REQUIRED_USE}"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
dev-lua/say[${LUA_USEDEP}]
|
|
${LUA_DEPS}
|
|
"
|
|
|
|
BDEPEND="
|
|
virtual/pkgconfig
|
|
test? (
|
|
dev-lua/busted[${LUA_USEDEP}]
|
|
${RDEPEND}
|
|
)
|
|
"
|
|
|
|
DEPEND="${RDEPEND}"
|
|
|
|
PATCHES=( "${FILESDIR}/${PN}-1.8.0-disable-highlightcolor-test.patch" )
|
|
|
|
lua_src_test() {
|
|
busted --lua=${ELUA} || die
|
|
}
|
|
|
|
src_test() {
|
|
lua_foreach_impl lua_src_test
|
|
}
|
|
|
|
lua_src_install() {
|
|
insinto $(lua_get_lmod_dir)/luassert
|
|
doins -r src/.
|
|
|
|
einstalldocs
|
|
}
|
|
|
|
src_install() {
|
|
lua_foreach_impl lua_src_install
|
|
}
|