mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-06 12:58:16 -07:00
c5455e9e02
* Excluding xorg.freedesktop.org * Excluding tango.freedesktop.org The following modified ebuilds were found to have problems after modification but the problems were determined to not be a regression. Upstream tarball has a new hash: * app-misc/evtest-1.29 * app-misc/evtest-1.30 * dev-embedded/scratchbox2-2.0-r1 * dev-ml/cairo-ocaml-1.2.0 * net-libs/libqmi-1.0.0 * sys-auth/libfprint-0.4.0 * sys-auth/libfprint-0.5.0 * sys-auth/libfprint-0.5.1 Upstream tarball has been deleted: * dev-libs/liblazy-0.2 * dev-util/pkgconfig-openbsd-20130507-r1 * x11-libs/xvba-video-0.8.0-r3 * x11-misc/driconf-0.9.1-r1 * x11-misc/xdg-utils-1.1.0_rc2-r1
53 lines
1.3 KiB
Bash
53 lines
1.3 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
GCONF_DEBUG="no"
|
|
VALA_USE_DEPEND="vapigen"
|
|
|
|
inherit eutils gnome2 multilib-minimal vala
|
|
|
|
DESCRIPTION="GObject wrapper for libusb"
|
|
HOMEPAGE="https://github.com/hughsie/libgusb"
|
|
SRC_URI="https://people.freedesktop.org/~hughsient/releases/${P}.tar.xz"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="0"
|
|
KEYWORDS="alpha amd64 ~arm hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc x86"
|
|
|
|
IUSE="+introspection static-libs vala"
|
|
REQUIRED_USE="vala? ( introspection )"
|
|
|
|
# Yes, we really need API from dev-libs/libusb-1.0.19, not virtual/libusb
|
|
RDEPEND="
|
|
>=dev-libs/glib-2.28:2[${MULTILIB_USEDEP}]
|
|
virtual/libusb:1[udev,${MULTILIB_USEDEP}]
|
|
introspection? ( >=dev-libs/gobject-introspection-1.29:= )
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
dev-libs/libxslt
|
|
dev-util/gtk-doc-am
|
|
virtual/pkgconfig[${MULTILIB_USEDEP}]
|
|
vala? ( $(vala_depend) )
|
|
"
|
|
|
|
# Tests try to access usb devices in /dev
|
|
RESTRICT="test"
|
|
|
|
multilib_src_configure() {
|
|
ECONF_SOURCE=${S} \
|
|
gnome2_src_configure \
|
|
$(multilib_native_use_enable introspection) \
|
|
$(use_enable static-libs static) \
|
|
$(multilib_native_use_enable vala)
|
|
|
|
if multilib_is_native_abi; then
|
|
ln -s "${S}"/docs/api/html docs/api/html || die
|
|
fi
|
|
}
|
|
|
|
multilib_src_install() {
|
|
gnome2_src_install
|
|
}
|