mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-23 18:38:08 -07:00
70 lines
1.8 KiB
Bash
70 lines
1.8 KiB
Bash
# Copyright 2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
MY_P="opentelemetry-python-${PV}"
|
|
|
|
DISTUTILS_USE_PEP517=hatchling
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="OpenTelemetry Semantic Conventions"
|
|
HOMEPAGE="
|
|
https://opentelemetry.io/
|
|
https://pypi.org/project/opentelemetry-sdk/
|
|
https://github.com/open-telemetry/opentelemetry-python/
|
|
"
|
|
SRC_URI="
|
|
https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
|
|
-> ${MY_P}.gh.tar.gz
|
|
"
|
|
S="${WORKDIR}/${MY_P}/${PN}"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm64 x86"
|
|
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/asgiref[${PYTHON_USEDEP}]
|
|
dev-python/attrs[${PYTHON_USEDEP}]
|
|
dev-python/deprecated[${PYTHON_USEDEP}]
|
|
dev-python/flaky[${PYTHON_USEDEP}]
|
|
dev-python/importlib-metadata[${PYTHON_USEDEP}]
|
|
dev-python/iniconfig[${PYTHON_USEDEP}]
|
|
dev-python/packaging[${PYTHON_USEDEP}]
|
|
dev-python/pluggy[${PYTHON_USEDEP}]
|
|
dev-python/py-cpuinfo[${PYTHON_USEDEP}]
|
|
dev-python/py[${PYTHON_USEDEP}]
|
|
dev-python/tomli[${PYTHON_USEDEP}]
|
|
dev-python/typing-extensions[${PYTHON_USEDEP}]
|
|
dev-python/wrapt[${PYTHON_USEDEP}]
|
|
dev-python/zipp[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# Use the same version with all opentelemetry components
|
|
# https://github.com/gentoo/gentoo/pull/35962#issuecomment-2025466313
|
|
sed -i -e "s/\(__version__ =\) .*/\1 \"${PV}\"/" src/opentelemetry/semconv/version.py || die
|
|
}
|
|
|
|
python_test() {
|
|
cp -a "${BUILD_DIR}"/{install,test} || die
|
|
local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
|
|
|
|
for dep in opentelemetry-api opentelemetry-sdk tests/opentelemetry-test-utils ; do
|
|
pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
|
|
distutils_pep517_install "${BUILD_DIR}"/test
|
|
popd >/dev/null || die
|
|
done
|
|
|
|
epytest
|
|
}
|