mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-04 04:57:07 -08:00
Anthony Ryan
8b0bacf3e4
All links to www.github.com were changed to github.com (preferred by GitHub). During the automated testing of all modified packages the following SRC_URIs were discovered to have changed upstream. Upon closer inspection they were all confirmed to not be regressions. They will all continue to work when served from the mirrors. * dev-python/catkin_pkg-0.2.10 (upstream tarball changed) * dev-python/rosdistro-0.4.4 (upstream tarball changed) * dev-util/rosdep-0.11.4 (upstream tarball changed) * dev-util/wstool-0.1.12 (upstream tarball changed) * dev-util/wstool-0.1.13 (upstream tarball changed) * dev-util/rosdep-0.11.5 (upstream tarball deleted)
64 lines
1.4 KiB
Bash
64 lines
1.4 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Python to GNU Octave bridge"
|
|
HOMEPAGE="
|
|
https://pypi.python.org/pypi/oct2py
|
|
http://pythonhosted.org/oct2py/
|
|
https://github.com/blink1073/oct2py"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
|
|
IUSE="doc examples test"
|
|
|
|
RDEPEND="
|
|
>=dev-python/numpy-1.7.1[${PYTHON_USEDEP}]
|
|
>=sci-libs/scipy-0.12[${PYTHON_USEDEP}]
|
|
sci-mathematics/octave"
|
|
DEPEND="${RDEPEND}
|
|
doc? (
|
|
dev-python/sphinx-bootstrap-theme[${PYTHON_USEDEP}]
|
|
dev-python/numpydoc[${PYTHON_USEDEP}]
|
|
)
|
|
test? (
|
|
dev-python/nose[${PYTHON_USEDEP}]
|
|
dev-python/ipython[${PYTHON_USEDEP}]
|
|
)"
|
|
|
|
python_prepare_all() {
|
|
# https://github.com/blink1073/oct2py/issues/77
|
|
sed \
|
|
-e 's:test_help:disabled:g' \
|
|
-i oct2py/tests/test_usage.py || die
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
if use doc; then
|
|
sphinx-build docs html || die
|
|
fi
|
|
}
|
|
|
|
python_test() {
|
|
unset DISPLAY
|
|
if [[ ${EPYTHON} == python2.7 ]]; then
|
|
local OPTIONS="--with-doctest"
|
|
fi
|
|
nosetests --exe -v oct2py ${OPTIONS} || die "Tests fail with ${EPYTHON}"
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( html/. )
|
|
use examples && EXAMPLES=( example/. )
|
|
distutils-r1_python_install_all
|
|
}
|