mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-03 23:47:28 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
56 lines
1.4 KiB
Bash
56 lines
1.4 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
PYTHON_REQ_USE='sqlite?'
|
|
PYTHON_COMPAT=( python2_7 )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="OpenID support for servers and consumers"
|
|
HOMEPAGE="http://www.openidenabled.com/openid/libraries/python/ http://pypi.python.org/pypi/python-openid"
|
|
# Downloaded from http://github.com/openid/python-openid/downloads
|
|
SRC_URI="mirror://gentoo/${P}.tar.gz"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86"
|
|
IUSE="examples mysql postgres sqlite test"
|
|
|
|
RDEPEND="mysql? ( >=dev-python/mysql-python-1.2.2[${PYTHON_USEDEP}] )
|
|
postgres? ( dev-python/psycopg[${PYTHON_USEDEP}] )"
|
|
DEPEND="${RDEPEND}
|
|
test? ( dev-python/twill
|
|
dev-python/pycurl )"
|
|
S="${WORKDIR}/openid-python-openid-b666238"
|
|
|
|
python_prepare_all() {
|
|
local PATCHES=(
|
|
# Patch to fix confusion with localhost/127.0.0.1
|
|
"${FILESDIR}/${PN}-2.0.0-gentoo-test_fetchers.diff"
|
|
)
|
|
|
|
# Disable broken tests from from examples/djopenid.
|
|
# Remove test that requires running db server.
|
|
sed -e "s/django_failures =.*/django_failures = 0/" \
|
|
-e '/storetest/d' \
|
|
-i admin/runtests || die "sed admin/runtests failed"
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_test() {
|
|
"${PYTHON}" admin/runtests || die "Tests fail with ${EPYTHON}"
|
|
}
|
|
|
|
python_install_all() {
|
|
distutils-r1_python_install_all
|
|
|
|
if use examples; then
|
|
dodoc -r examples
|
|
docompress -x /usr/share/doc/${PF}/examples
|
|
fi
|
|
}
|