mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-10 15:47:28 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
57 lines
1.2 KiB
Bash
57 lines
1.2 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
PYTHON_COMPAT=( python2_7 )
|
|
|
|
inherit autotools-utils eutils python-r1
|
|
|
|
DESCRIPTION="Python bindings for libnotify"
|
|
HOMEPAGE="http://www.galago-project.org/"
|
|
SRC_URI="http://www.galago-project.org/files/releases/source/${PN}/${P}.tar.bz2"
|
|
|
|
LICENSE="LGPL-2.1"
|
|
SLOT="0"
|
|
KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 ~sh sparc x86 ~x86-fbsd"
|
|
IUSE="examples"
|
|
|
|
RDEPEND="
|
|
>=dev-python/pygtk-2.24:2[${PYTHON_USEDEP}]
|
|
>=x11-libs/libnotify-0.7"
|
|
DEPEND="${RDEPEND}
|
|
virtual/pkgconfig"
|
|
|
|
PATCHES=( "${FILESDIR}"/${P}-libnotify-0.7.patch )
|
|
|
|
src_prepare() {
|
|
# Remove the old pynotify.c to ensure it's properly regenerated #212128.
|
|
rm -f src/pynotify.c || die
|
|
autotools-utils_src_prepare
|
|
}
|
|
|
|
src_configure() {
|
|
python_foreach_impl autotools-utils_src_configure
|
|
}
|
|
|
|
src_compile() {
|
|
python_foreach_impl autotools-utils_src_compile
|
|
}
|
|
|
|
src_test() {
|
|
python_foreach_impl autotools-utils_src_test
|
|
}
|
|
|
|
src_install() {
|
|
python_foreach_impl autotools-utils_src_install
|
|
prune_libtool_files --all
|
|
|
|
# Requested from bug 351879.
|
|
if use examples; then
|
|
docinto examples
|
|
dodoc tests/*.{png,py}
|
|
docompress -x /usr/share/doc/${PF}/examples
|
|
fi
|
|
}
|