mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-11 03:57:28 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
50 lines
1.4 KiB
Bash
50 lines
1.4 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
|
|
|
|
inherit distutils-r1 vcs-snapshot
|
|
|
|
DESCRIPTION="A CSS Cascading Style Sheets library"
|
|
HOMEPAGE="http://pypi.python.org/pypi/cssutils/ https://bitbucket.org/cthedot/cssutils"
|
|
# Missing test data
|
|
# https://bitbucket.org/cthedot/cssutils/pull-request/11
|
|
#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
|
|
HG_COMMIT="6fbc1877f6089610b733a92d21c2bbf25dc1ca28"
|
|
SRC_URI="https://bitbucket.org/cthedot/cssutils/get/${HG_COMMIT}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="GPL-3"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm ~ppc ~x86"
|
|
IUSE="examples test"
|
|
|
|
RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
test? ( dev-python/mock[${PYTHON_USEDEP}] )"
|
|
|
|
python_prepare_all() {
|
|
# Disable test failing with dev-python/pyxml installed.
|
|
if has_version dev-python/pyxml; then
|
|
sed -e "s/test_linecol/_&/" -i src/tests/test_errorhandler.py
|
|
fi
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_test() {
|
|
ln -s "${S}/sheets" "${BUILD_DIR}/sheets" || die
|
|
# exclude tests that connect to the network
|
|
set -- nosetests \
|
|
-e test_parseUrl -e test_handlers -P "${BUILD_DIR}/lib/cssutils/tests"
|
|
echo "$@"
|
|
"$@" || die "Testing failed with ${EPYTHON}"
|
|
}
|
|
|
|
python_install_all() {
|
|
use examples && local EXAMPLES=( examples/. )
|
|
distutils-r1_python_install_all
|
|
}
|