mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-07 00:47:39 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
53 lines
1.1 KiB
Bash
53 lines
1.1 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
|
|
EGIT_REPO_URI="https://github.com/cinemast/${PN}"
|
|
EGIT_BRANCH=develop
|
|
inherit cmake-utils git-r3
|
|
|
|
DESCRIPTION="JSON-RPC (1.0 & 2.0) framework for C++"
|
|
HOMEPAGE="https://github.com/cinemast/libjson-rpc-cpp"
|
|
SRC_URI=""
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS=""
|
|
IUSE="doc +http-client +http-server +stubgen test"
|
|
|
|
RDEPEND="
|
|
dev-libs/jsoncpp:=
|
|
http-client? ( net-misc/curl:= )
|
|
http-server? ( net-libs/libmicrohttpd:= )
|
|
stubgen? ( dev-libs/argtable:= )"
|
|
DEPEND="${RDEPEND}
|
|
doc? ( app-doc/doxygen )
|
|
test? ( dev-libs/boost )"
|
|
|
|
src_configure() {
|
|
local mycmakeargs=(
|
|
-DHTTP_CLIENT=$(usex http-client)
|
|
-DHTTP_SERVER=$(usex http-server)
|
|
# they are not installed
|
|
-DCOMPILE_EXAMPLES=NO
|
|
-DCOMPILE_STUBGEN=$(usex stubgen)
|
|
-DCOMPILE_TESTS=$(usex test)
|
|
)
|
|
|
|
cmake-utils_src_configure
|
|
}
|
|
|
|
src_compile() {
|
|
cmake-utils_src_compile
|
|
|
|
use doc && emake -C "${BUILD_DIR}" doc
|
|
}
|
|
|
|
src_install() {
|
|
cmake-utils_src_install
|
|
|
|
use doc && dodoc -r "${BUILD_DIR}"/doc/html
|
|
}
|