mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-04 04:57:07 -08:00
60 lines
1.5 KiB
Bash
60 lines
1.5 KiB
Bash
# Copyright 1999-2017 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=6
|
|
|
|
PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
|
|
PYTHON_REQ_USE='xml(+),threads(+)'
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="CLI for extracting streams from websites to a video player of your choice"
|
|
HOMEPAGE="https://streamlink.github.io/"
|
|
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
KEYWORDS="~amd64 ~x86"
|
|
LICENSE="BSD-2 Apache-2.0"
|
|
SLOT="0"
|
|
IUSE="doc test"
|
|
|
|
RDEPEND="dev-python/pycryptodome[${PYTHON_USEDEP}]
|
|
dev-python/requests[${PYTHON_USEDEP}]
|
|
virtual/python-futures[${PYTHON_USEDEP}]
|
|
virtual/python-singledispatch[${PYTHON_USEDEP}]
|
|
dev-python/backports-shutil_which[$(python_gen_usedep 'python2*')]
|
|
$(python_gen_cond_dep 'dev-python/backports-shutil_get_terminal_size[${PYTHON_USEDEP}]' 'python2*')
|
|
dev-python/pycountry[${PYTHON_USEDEP}]
|
|
dev-python/websocket-client[${PYTHON_USEDEP}]
|
|
media-video/rtmpdump
|
|
virtual/ffmpeg"
|
|
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
|
|
doc? (
|
|
dev-python/sphinx[${PYTHON_USEDEP}]
|
|
dev-python/docutils[${PYTHON_USEDEP}]
|
|
)
|
|
test? (
|
|
$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' 'python2*')
|
|
${RDEPEND}
|
|
)"
|
|
|
|
python_configure_all() {
|
|
# Avoid iso-639, iso3166 dependencies since we use pycountry.
|
|
export STREAMLINK_USE_PYCOUNTRY=1
|
|
}
|
|
|
|
python_compile_all() {
|
|
use doc && emake -C docs html man
|
|
}
|
|
|
|
python_test() {
|
|
esetup.py test
|
|
}
|
|
|
|
python_install_all() {
|
|
if use doc; then
|
|
local HTML_DOCS=( docs/_build/html/. )
|
|
doman docs/_build/man/*
|
|
fi
|
|
distutils-r1_python_install_all
|
|
}
|