mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-05 14:07:27 -08:00
55 lines
1.2 KiB
Bash
55 lines
1.2 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYPI_NO_NORMALIZE=1
|
|
PYTHON_TESTED=( python3_{11..14} pypy3_11 )
|
|
PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_{13,14}t )
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="Thin-wrapper around the mock package for easier use with pytest"
|
|
HOMEPAGE="
|
|
https://github.com/pytest-dev/pytest-mock/
|
|
https://pypi.org/project/pytest-mock/
|
|
"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
|
|
|
|
RDEPEND="
|
|
>=dev-python/pytest-6.2.5[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
dev-python/setuptools-scm[${PYTHON_USEDEP}]
|
|
test? (
|
|
$(python_gen_cond_dep '
|
|
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
|
|
' "${PYTHON_TESTED[@]}")
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
|
|
einfo "Skipping tests on ${EPYTHON}"
|
|
return
|
|
fi
|
|
|
|
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
|
|
local -x PYTEST_PLUGINS=pytest_mock,pytest_asyncio.plugin
|
|
local EPYTEST_DESELECT=()
|
|
|
|
if has_version dev-python/mock; then
|
|
EPYTEST_DESELECT+=(
|
|
tests/test_pytest_mock.py::test_standalone_mock
|
|
)
|
|
fi
|
|
|
|
epytest --assert=plain
|
|
}
|