mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-10 14:18:16 -07:00
89c2071207
keyword 1.11.1 for ~arm64-macos, ~x64-macos dev-python/gast: keyword 0.5.3-r1 for ~arm64-macos, ~x64-macos dev-python/beniget: keyword 0.4.1-r1 for ~arm64-macos, ~x64-macos dev-python/pythran: keyword 0.13.1 for ~arm64-macos, ~x64-macos sci-libs/gklib: keyword 5.1.1_p20230327-r1 for ~arm64-macos, ~x64-macos sci-libs/metis: keyword 5.2.1-r2 for ~arm64-macos, ~x64-macos sci-libs/ccolamd: keyword 2.9.6 for ~arm64-macos, ~x64-macos sci-libs/camd: keyword 2.4.6-r1 for ~arm64-macos, ~x64-macos sci-libs/colamd: keyword 2.9.6 for ~arm64-macos, ~x64-macos sci-libs/cholmod: keyword 3.0.14 for ~arm64-macos, ~x64-macos sci-libs/suitesparseconfig: keyword 5.4.0 for ~arm64-macos, ~x64-macos sci-libs/amd: keyword 2.4.6-r1 for ~arm64-macos, ~x64-macos sci-libs/umfpack: keyword 5.7.9 for ~arm64-macos, ~x64-macos sci-libs/arpack: keyword 3.8.0 for ~arm64-macos, ~x64-macos dev-python/charset-normalizer: keyword 3.2.0 for ~arm64-macos, ~x64-macos dev-python/requests: keyword 2.31.0 for ~arm64-macos, ~x64-macos dev-python/pooch: keyword 1.7.0 for ~arm64-macos, ~x64-macos Signed-off-by: Benda Xu <heroxbd@gentoo.org>
71 lines
1.7 KiB
Bash
71 lines
1.7 KiB
Bash
# Copyright 2021-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_TESTED=( python3_{9..11} )
|
|
PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
|
|
|
|
inherit distutils-r1 multiprocessing
|
|
|
|
MY_P=${P/_p/.post}
|
|
DESCRIPTION="Ahead of Time compiler for numeric kernels"
|
|
HOMEPAGE="
|
|
https://pypi.org/project/pythran/
|
|
https://github.com/serge-sans-paille/pythran/
|
|
"
|
|
SRC_URI="
|
|
https://github.com/serge-sans-paille/pythran/archive/${PV/_p/.post}.tar.gz
|
|
-> ${MY_P}.gh.tar.gz
|
|
"
|
|
S=${WORKDIR}/${MY_P}
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm arm64 ~ia64 ~loong ~ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
|
|
|
|
RDEPEND="
|
|
dev-libs/boost
|
|
=dev-python/beniget-0.4*[${PYTHON_USEDEP}]
|
|
=dev-python/gast-0.5*[${PYTHON_USEDEP}]
|
|
dev-python/numpy[${PYTHON_USEDEP}]
|
|
>=dev-python/ply-3.4[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
$(python_gen_cond_dep '
|
|
dev-python/ipython[${PYTHON_USEDEP}]
|
|
' "${PYTHON_TESTED[@]}")
|
|
dev-python/pytest-xdist[${PYTHON_USEDEP}]
|
|
dev-python/scipy[${PYTHON_USEDEP}]
|
|
dev-python/wheel[${PYTHON_USEDEP}]
|
|
virtual/cblas
|
|
!!dev-python/setuptools-declarative-requirements
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
src_configure() {
|
|
# TODO: package xsimd then set no_xsimd = True
|
|
cat >> setup.cfg <<-EOF
|
|
[build_py]
|
|
no_boost = True
|
|
EOF
|
|
}
|
|
|
|
python_test() {
|
|
local EPYTEST_DESELECT=(
|
|
# TODO
|
|
pythran/tests/test_xdoc.py::TestDoctest::test_cli
|
|
pythran/tests/test_xdoc.py::TestDoctest::test_toolchain
|
|
# Tries to invoke pip
|
|
pythran/tests/test_distutils.py::TestDistutils::test_setup_build
|
|
pythran/tests/test_distutils.py::TestDistutils::test_setup_build2
|
|
)
|
|
|
|
local -x COLUMNS=80
|
|
epytest -n "$(makeopts_jobs)"
|
|
}
|