mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-12 14:58:07 -07:00
5dfbd9a97d
keyword 0-r1 for ~arm64-macos dev-cpp/eigen: keyword 3.4.0-r1 for ~arm64-macos, ~x64-macos dev-python/pyproject-metadata: keyword 0.7.1 for ~arm64-macos, ~x64-macos dev-python/appdirs: keyword 1.4.4-r3 for ~arm64-macos dev-python/fs: keyword 2.4.16 for ~arm64-macos, ~x64-macos dev-python/cppy: keyword 1.2.1-r1 for ~arm64-macos, ~x64-macos dev-python/olefile: keyword 0.46-r2 for ~arm64-macos, ~x64-macos media-libs/libwebp: keyword 1.3.1 for ~arm64-macos media-libs/qhull: keyword 2020.2-r3 for ~arm64-macos media-fonts/stix-fonts: keyword 2.11 for ~arm64-macos media-fonts/dejavu: keyword 2.37 for ~arm64-macos, ~x64-macos dev-python/pytz: keyword 2023.3-r1 for ~arm64-macos dev-python/pillow: keyword 10.0.0 for ~arm64-macos, ~x64-macos dev-python/kiwisolver: keyword 1.4.4-r1 for ~arm64-macos, ~x64-macos dev-python/fonttools: keyword 4.41.0 for ~arm64-macos dev-python/cycler: keyword 0.11.0-r1 for ~arm64-macos dev-python/contourpy: keyword 1.1.0 for ~arm64-macos, ~x64-macos Signed-off-by: Benda Xu <heroxbd@gentoo.org>
68 lines
1.6 KiB
Bash
68 lines
1.6 KiB
Bash
# Copyright 1999-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_EXT=1
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{10..11} )
|
|
PYTHON_REQ_USE="xml(+)"
|
|
|
|
inherit distutils-r1 virtualx
|
|
|
|
DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
|
|
HOMEPAGE="
|
|
https://github.com/fonttools/fonttools/
|
|
https://pypi.org/project/fonttools/
|
|
"
|
|
SRC_URI="
|
|
https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
|
|
-> ${P}.gh.tar.gz
|
|
"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
|
|
|
|
RDEPEND="
|
|
>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
dev-python/cython[${PYTHON_USEDEP}]
|
|
test? (
|
|
app-arch/brotli[python,${PYTHON_USEDEP}]
|
|
app-arch/zopfli
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_prepare_all() {
|
|
# When dev-python/pytest-shutil is installed, we get weird import errors.
|
|
# This is due to incomplete nesting in the Tests/ tree:
|
|
#
|
|
# Tests/feaLib/__init__.py
|
|
# Tests/ufoLib/__init__.py
|
|
# Tests/svgLib/path/__init__.py
|
|
# Tests/otlLib/__init__.py
|
|
# Tests/varLib/__init__.py
|
|
#
|
|
# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
|
|
touch Tests/svgLib/__init__.py || die
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
src_configure() {
|
|
export FONTTOOLS_WITH_CYTHON=1
|
|
}
|
|
|
|
src_test() {
|
|
# virtualx used when matplotlib is installed causing plot module tests to run
|
|
virtx distutils-r1_src_test
|
|
}
|
|
|
|
python_test() {
|
|
epytest Tests fontTools || die "Tests failed with ${EPYTHON}"
|
|
}
|