mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-07-25 08:58:27 -07:00
8294637aad
Remove jaraco.tidelift dependency from docs. No revbump, as no affect for [-doc], and [doc] was failing to build (as we don't have this dependency, or if it came from an overlay, this is just meens they have a little different doc). Closes: https://bugs.gentoo.org/831633 Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
53 lines
1.3 KiB
Bash
53 lines
1.3 KiB
Bash
# Copyright 1999-2022 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( pypy3 python3_{8..10} )
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Provides access to the system keyring service"
|
|
HOMEPAGE="https://github.com/jaraco/keyring"
|
|
SRC_URI="https://github.com/jaraco/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
SLOT="0"
|
|
LICENSE="PSF-2"
|
|
KEYWORDS="~alpha amd64 arm arm64 hppa ppc ppc64 ~riscv sparc x86 ~x64-macos"
|
|
|
|
RDEPEND="
|
|
dev-python/secretstorage[${PYTHON_USEDEP}]
|
|
dev-python/entrypoints[${PYTHON_USEDEP}]
|
|
dev-python/jeepney[${PYTHON_USEDEP}]
|
|
dev-python/importlib_metadata[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
dev-python/setuptools_scm[${PYTHON_USEDEP}]
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
distutils_enable_sphinx docs \
|
|
dev-python/jaraco-packaging \
|
|
dev-python/rst-linker
|
|
|
|
export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
|
|
|
|
EPYTEST_DESELECT=(
|
|
# this test fails if importlib-metadata returns more than one
|
|
# entry, i.e. when keyring is installed already
|
|
tests/test_packaging.py::test_entry_point
|
|
)
|
|
|
|
EPYTEST_IGNORE=(
|
|
# apparently does not unlock the keyring properly
|
|
tests/backends/test_libsecret.py
|
|
# hangs
|
|
tests/backends/test_kwallet.py
|
|
)
|
|
|
|
src_prepare() {
|
|
# remove jaraco.tidelift dependency from docs, quite useless
|
|
sed -e '/tidelift/d' -i docs/conf.py docs/index.rst || die
|
|
|
|
distutils-r1_src_prepare
|
|
}
|