mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-30 04:47:28 -07:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
70 lines
1.7 KiB
Bash
70 lines
1.7 KiB
Bash
# Copyright 1999-2014 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_PN="Flask-Cors"
|
|
MY_P="${MY_PN}-${PV}"
|
|
|
|
if [[ "${PV}" == "9999" ]]; then
|
|
inherit git-2
|
|
EGIT_REPO_URI="git://github.com/wcdolphin/${PN}.git"
|
|
SRC_URI=""
|
|
else
|
|
SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
|
|
fi
|
|
|
|
DESCRIPTION="A Flask extension for Cross Origin Resource Sharing (CORS)"
|
|
HOMEPAGE="https://github.com/wcdolphin/flask-cors https://pypi.python.org/pypi/Flask-Cors"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="doc test"
|
|
|
|
RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
|
|
dev-python/six[${PYTHON_USEDEP}]"
|
|
DEPEND="
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
doc? (
|
|
${RDEPEND}
|
|
dev-python/sphinx[${PYTHON_USEDEP}]
|
|
>=dev-python/python-docs-2.7.6-r1:2.7
|
|
dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
|
|
)
|
|
test? (
|
|
${RDEPEND}
|
|
dev-python/nose[${PYTHON_USEDEP}]
|
|
)"
|
|
|
|
S="${WORKDIR}/${MY_P}"
|
|
|
|
python_prepare_all() {
|
|
if use doc; then
|
|
local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
|
|
local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
|
|
local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
|
|
local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
|
|
sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
|
|
fi
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
use doc && emake -C docs html
|
|
}
|
|
|
|
python_test() {
|
|
esetup.py test
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( docs/_build/html/. )
|
|
|
|
distutils-r1_python_install_all
|
|
}
|