mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-05-31 15:07:28 -07:00
812ed0dc59
This is unfortunate but it's needed given abseil-cpp needs it for some of the libraries it installs. An alternative would be to control the helpers with USE=testlib or something, I guess. Fixes: 53bb853b51f0ccdacba1714a9405e23fbdd96ce2 Bug: https://bugs.gentoo.org/915902 Closes: https://bugs.gentoo.org/934175 Signed-off-by: Sam James <sam@gentoo.org>
63 lines
1.6 KiB
Bash
63 lines
1.6 KiB
Bash
# Copyright 2020-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{10..12} )
|
|
|
|
inherit cmake-multilib python-any-r1
|
|
|
|
DESCRIPTION="Abseil Common Libraries (C++), LTS Branch"
|
|
HOMEPAGE="https://abseil.io/"
|
|
SRC_URI="https://github.com/abseil/abseil-cpp/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0/${PV%%.*}"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~sparc ~x86"
|
|
IUSE="test"
|
|
|
|
RDEPEND=">=dev-cpp/gtest-1.13.0[${MULTILIB_USEDEP}]"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
${PYTHON_DEPS}
|
|
test? (
|
|
sys-libs/timezone-data
|
|
)
|
|
"
|
|
|
|
RESTRICT="!test? ( test )"
|
|
PATCHES=( "${FILESDIR}/${PN}-20230802.0-sdata-tests.patch" )
|
|
|
|
src_prepare() {
|
|
cmake_src_prepare
|
|
|
|
# un-hardcode abseil compiler flags
|
|
sed -i \
|
|
-e '/"-maes",/d' \
|
|
-e '/"-msse4.1",/d' \
|
|
-e '/"-mfpu=neon"/d' \
|
|
-e '/"-march=armv8-a+crypto"/d' \
|
|
absl/copts/copts.py || die
|
|
|
|
# now generate cmake files
|
|
python_fix_shebang absl/copts/generate_copts.py
|
|
absl/copts/generate_copts.py || die
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
local mycmakeargs=(
|
|
# We use -std=c++14 here so that abseil-cpp's string_view is used
|
|
# See the discussion in https://github.com/gentoo/gentoo/pull/32281.
|
|
-DCMAKE_CXX_STANDARD=14
|
|
-DABSL_ENABLE_INSTALL=TRUE
|
|
-DABSL_USE_EXTERNAL_GOOGLETEST=ON
|
|
-DABSL_PROPAGATE_CXX_STD=TRUE
|
|
# TEST_HELPERS needed for protobuf (bug #915902)
|
|
-DABSL_BUILD_TEST_HELPERS=ON
|
|
-DABSL_BUILD_TESTING=$(usex test ON OFF)
|
|
$(usex test -DBUILD_TESTING=ON '') # intentional usex, it used both variables for tests.
|
|
)
|
|
|
|
cmake_src_configure
|
|
}
|