mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-29 04:27:34 -07:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
81 lines
2.4 KiB
Bash
81 lines
2.4 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="HTTP library with thread-safe connection pooling, file post, and more"
|
|
HOMEPAGE="https://github.com/shazow/urllib3"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 arm ~hppa ~ppc ~ppc64 ~x86"
|
|
IUSE="doc test"
|
|
|
|
RDEPEND="dev-python/six[${PYTHON_USEDEP}]
|
|
$(python_gen_cond_dep \
|
|
'dev-python/backports-ssl-match-hostname[${PYTHON_USEDEP}]' python2_7 pypy)"
|
|
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
|
|
test? (
|
|
${RDEPEND}
|
|
~www-servers/tornado-3.1.1[${PYTHON_USEDEP}]
|
|
$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy)
|
|
dev-python/nose[${PYTHON_USEDEP}] )
|
|
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
|
|
"
|
|
|
|
python_prepare_all() {
|
|
# Replace bundled copy of dev-python/six
|
|
cat > urllib3/packages/six.py <<-EOF
|
|
from __future__ import absolute_import
|
|
from six import *
|
|
EOF
|
|
|
|
sed -i 's:cover-min-percentage = 100::' setup.cfg || die
|
|
# Fix tests
|
|
sed -i 's/urllib3.packages.six/six/' test/test_retry.py || die
|
|
|
|
# Reset source of objects.inv
|
|
if use doc; then
|
|
local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
|
|
local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
|
|
local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
|
|
local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
|
|
sed -i "s|'python': ('http://docs.python.org/2.7', None|'${PYTHON_DOC}': ('${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
|
|
fi
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
use doc && emake -C docs html
|
|
}
|
|
|
|
python_test() {
|
|
# __init__.py uses a local import requiring use of PYTHONPATH=blank to offset
|
|
# Failures currently occur under py2.7. After joint testing
|
|
# it's planned for this to have further investigation.
|
|
# https://github.com/shazow/urllib3/issues/621
|
|
|
|
# These tests fail with network-sandbox enable due to an arbitrary "tarpit"
|
|
# address (10.255.255.1) being non-routable.
|
|
local exclude=(
|
|
-e test_enhanced_timeout
|
|
-e test_https_timeout
|
|
-e test_https_proxy_pool_timeout
|
|
-e test_https_proxy_timeout
|
|
)
|
|
|
|
PYTHONPATH= nosetests "${exclude[@]}" test || die "Tests fail with ${EPYTHON}"
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( docs/_build/html/. )
|
|
|
|
distutils-r1_python_install_all
|
|
}
|