mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-06 00:27:27 -08:00
56bd759df1
This commit represents a new era for Gentoo: Storing the gentoo-x86 tree in Git, as converted from CVS. This commit is the start of the NEW history. Any historical data is intended to be grafted onto this point. Creation process: 1. Take final CVS checkout snapshot 2. Remove ALL ChangeLog* files 3. Transform all Manifests to thin 4. Remove empty Manifests 5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$ 5.1. Do not touch files with -kb/-ko keyword flags. Signed-off-by: Robin H. Johnson <robbat2@gentoo.org> X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
69 lines
1.6 KiB
Bash
69 lines
1.6 KiB
Bash
# Copyright 1999-2015 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Id$
|
|
|
|
EAPI=5
|
|
PYTHON_COMPAT=( python{2_7,3_3,3_4} ) # Tests crash with pypy
|
|
inherit distutils-r1 flag-o-matic prefix
|
|
|
|
DESCRIPTION="Tools for generating printable PDF documents from any data source"
|
|
HOMEPAGE="http://www.reportlab.com/"
|
|
SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz
|
|
http://www.reportlab.com/ftp/fonts/pfbfer-20070710.zip"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
|
|
IUSE="doc examples"
|
|
|
|
RDEPEND="
|
|
>=dev-python/pillow-2.4.0[tiff,truetype,${PYTHON_USEDEP}]
|
|
>=dev-python/pip-1.4.1[${PYTHON_USEDEP}]
|
|
>=dev-python/setuptools-2.2[${PYTHON_USEDEP}]
|
|
media-libs/libart_lgpl
|
|
sys-libs/zlib
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
app-arch/unzip
|
|
"
|
|
|
|
src_unpack() {
|
|
unpack ${P}.tar.gz
|
|
cd ${P}/src/reportlab/fonts || die
|
|
unpack pfbfer-20070710.zip
|
|
}
|
|
|
|
python_prepare_all() {
|
|
sed -i \
|
|
-e 's|/usr/local/Acrobat|/opt/Acrobat|g' \
|
|
-e 's|%(HOME)s/fonts|%(HOME)s/.fonts|g' \
|
|
src/reportlab/rl_config.py || die
|
|
|
|
eprefixify setup.py
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
use doc && emake -C docs html
|
|
}
|
|
|
|
python_compile() {
|
|
if ! python_is_python3; then
|
|
local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
|
|
fi
|
|
distutils-r1_python_compile
|
|
}
|
|
|
|
python_test() {
|
|
pushd tests > /dev/null || die
|
|
"${PYTHON}" runAll.py || die "Testing failed with ${EPYTHON}"
|
|
popd > /dev/null || die
|
|
}
|
|
|
|
python_install_all() {
|
|
use doc && local HTML_DOCS=( docs/build/html/. )
|
|
use examples && local EXAMPLES=( demos/. tools/pythonpoint/demos )
|
|
|
|
distutils-r1_python_install_all
|
|
}
|