Files
gentoo/dev-embedded/u-boot-tools/u-boot-tools-2019.10.ebuild
T
Mikle Kolyada 078daa2061 dev-embedded/u-boot-tools: arm stable wrt bug #705596
Package-Manager: Portage-2.3.84, Repoman-2.3.20
RepoMan-Options: --include-arches="arm"
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
2020-01-27 14:24:16 +03:00

61 lines
1.2 KiB
Bash

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit toolchain-funcs
MY_P="u-boot-${PV/_/-}"
DESCRIPTION="utilities for working with Das U-Boot"
HOMEPAGE="https://www.denx.de/wiki/U-Boot/WebHome"
SRC_URI="ftp://ftp.denx.de/pub/u-boot/${MY_P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 arm ~arm64 ~ppc64 x86"
IUSE=""
DEPEND="
sys-devel/flex
sys-devel/bison
"
S=${WORKDIR}/${MY_P}
PATCHES=("${FILESDIR}"/${P}-musl-ulong.patch)
src_compile() {
# Unset a few KBUILD variables. Bug #540476
unset KBUILD_OUTPUT KBUILD_SRC
emake \
V=1 \
HOSTCC="$(tc-getCC)" \
HOSTCFLAGS="${CFLAGS} ${CPPFLAGS}"' $(HOSTCPPFLAGS)' \
HOSTLDFLAGS="${LDFLAGS}" \
tools-only_defconfig
emake \
V=1 \
NO_SDL=1 \
HOSTSTRIP=: \
STRIP=: \
HOSTCC="$(tc-getCC)" \
HOSTCFLAGS="${CFLAGS} ${CPPFLAGS}"' $(HOSTCPPFLAGS)' \
HOSTLDFLAGS="${LDFLAGS}" \
CONFIG_ENV_OVERWRITE=y \
tools-all
}
src_test() { :; }
src_install() {
cd tools || die
dobin bmp_logo dumpimage fdtgrep gen_eth_addr img2srec mkenvimage mkimage
dobin env/fw_printenv
dosym fw_printenv /usr/bin/fw_setenv
insinto /etc
doins env/fw_env.config
doman "${S}"/doc/mkimage.1
}