Files
gentoo/dev-libs/spdlog/spdlog-1.9.2.ebuild
T
David Roman 64d406bdf1 dev-libs/spdlog: fix dependency version
Closes: https://bugs.gentoo.org/810496
Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: David Roman <davidroman96@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/22136
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
2021-08-27 22:01:51 -04:00

48 lines
943 B
Bash

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake
DESCRIPTION="Very fast, header only, C++ logging library"
HOMEPAGE="https://github.com/gabime/spdlog"
if [[ ${PV} == *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/gabime/${PN}"
else
SRC_URI="https://github.com/gabime/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
fi
LICENSE="MIT"
SLOT="0/1"
IUSE="test"
RESTRICT="!test? ( test )"
BDEPEND="
virtual/pkgconfig
"
DEPEND="
>=dev-libs/libfmt-8.0.0:=
"
RDEPEND="${DEPEND}"
src_prepare() {
cmake_src_prepare
rm -r include/spdlog/fmt/bundled || die "Failed to delete bundled libfmt"
}
src_configure() {
local mycmakeargs=(
-DSPDLOG_BUILD_BENCH=no
-DSPDLOG_BUILD_EXAMPLE=no
-DSPDLOG_FMT_EXTERNAL=yes
-DSPDLOG_BUILD_SHARED=yes
-DSPDLOG_BUILD_TESTS=$(usex test)
)
cmake_src_configure
}